Programmatically Completing A List Of Movie Showtimes In ColdFusion - Simplified

<!--- Define our list of raw showtimes. --->
<cfset showtimesList = "11:00 11:40AM 12:20 1:00 1:40 2:20 3:00 3:40 4:20 5:00 5:40 7:10 7:50 8:30 9:50 10:30 11:10PM 12:00 12:40AM" />

<!--- Define our collection of fleshed-out showtimes. --->
<cfset showtimes = [] />

<!---
	Create a fail-safe default TT for our movie showtime
	parsing. This way, we have something to go on (even if it
	turns out to be wrong.
--->
<cfset currentTT = "PM" />


<!--- Convert the showtime list into an array. --->
<cfset showtimesArray = listToArray( showtimesList, " " ) />

<!---
	Loop over it backwards; the known AM/PM values are at the end
	of every portion of the day; as such, if we loop over the list
	backwards, we should alawys run into known AM/PM values that
	define the unknow listings before it.
--->
<cfloop
	index="index"
	from="#arrayLen( showtimesArray )#"
	to="1"
	step="-1">


	<!--- Get the current showtime parts. --->
	<cfset showtimeParts = reMatchNoCase(
		"\d+:\d+|AM|PM",
		showtimesArray[ index ]
		) />

	<!---
		Check to see if there is a known AM/PM value at this point.
		If so, then we want to start using it going forwrad (er, um,
		backwards).
	--->
	<cfif (arrayLen( showtimeParts ) eq 2)>

		<!--- Use the new TT value. --->
		<cfset currentTT = showtimeParts[ 2 ] />

	</cfif>

	<!--- Create the new showtime entry. --->
	<cfset arrayPrepend(
		showtimes,
		(showtimeParts[ 1 ] & currentTT)
		) />


</cfloop>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!--- Output the original showtimes and our new showtimes. --->
<cfoutput>

	<strong>Original</strong>:

	#lcase( showtimesList )#

	<br />
	<br />

	<strong>Parsed</strong>:

	#lcase( arrayToList( showtimes, " " ) )#

</cfoutput>