Programmatically Completing A List Of Movie Showtimes In ColdFusion

<cffunction
	name="otherTT"
	access="public"
	returntype="string"
	output="false"
	hint="Given an AM/PM value, I return the opposite AM/PM value.">

	<!--- Define arguments. --->
	<cfargument
		name="tt"
		type="string"
		required="true"
		hint="I am either AM or PM."
		/>

	<!--- Check to see which value we currently have. --->
	<cfif (arguments.tt eq "AM")>

		<!--- Return opposite. --->
		<cfreturn "PM" />

	<cfelse>

		<!--- Return opposite. --->
		<cfreturn "AM" />

	</cfif>
</cffunction>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!--- Define our list of raw showtimes. --->
<cfset showtimesList = "11:00 11:15AM 1:15 1:35 1:50 4:10 4:25 6:30 6:50 8:50 9:20 10:50 12:00 12:30 12:45AM" />


<!--- Define our collection of fleshed-out showtimes. --->
<cfset showtimes = [] />


<!---
	We are going to run through the movie showtimes with an
	initial assumption that they start in the AM. If we come across
	any showtimes that contradict this, we'll go back through the
	showtimes and change the AM/PM markers.
--->
<cfset flipAMPM = false />

<!---
	We will start out by assuming that the first showtime will be
	in the AM. But, it doesn't really matter.
--->
<cfset prevTT = "AM" />

<!--- Keep track of the prevous time. --->
<cfset prevHHMM = "" />


<!---
	Keep a collection of known AM/PM values. This will help us deal
	with very outlier cases in which movie showtimes are spread
	extermely far apart.
--->
<cfset knownTT = {} />


<!---
	Loop over all the raw showtimes so that we can convert each one
	into a showtime containing both a HH:MM and a TT portion.
--->
<cfloop
	index="showtimeItem"
	list="#showtimesList#"
	delimiters=" ">


	<!--- Extract the HH:MM and the TT. --->
	<cfset showtimeParts = reMatchNoCase(
		"\d+:\d+|AM|PM",
		showtimeItem
		) />

	<!---
		Append the empty string just to simplify our logic. This way,
		the parts array will always have at least two indices.
	--->
	<cfset arrayAppend( showtimeParts, "" ) />


	<!--- Get the time-only value (without any AM/PM). --->
	<cfset thisHHMM = showtimeParts[ 1 ] />

	<!---
		Get the AM/PM part. If this was not provided in the raw
		showtime, then this will be an empty string.
	--->
	<cfset rawTT = showtimeParts[ 2 ] />


	<!--- Check to see if this is the first item. --->
	<cfif !arrayLen( showtimes )>


		<!---
			Check to see if a raw TT was provided. If so, then we
			just want to use it since it is the only "sure" thing
			we know at this point.
		--->
		<cfif len( rawTT )>

			<!--- Use the given TT. --->
			<cfset thisTT = rawTT />

		<cfelse>

			<!--- Assume that it was AM. --->
			<cfset thisTT = prevTT />

		</cfif>


		<!--- Construct the first time. --->
		<cfset thisTime = (thisHHMM & thisTT) />


	<cfelse>


		<!---
			At first, we will assume that this time as the same
			AM/PM as the previous time. However, if we are actually
			crossing over the divide, then this time will SMALLER
			than the previous time.
		--->
		<cfif ("#prevHHMM##prevTT#" lte "#thisHHMM##thisTT#")>

			<!---
				The times still appear to be asscending. This
				indicates that we have not jumped over any divide in
				the day.
			--->
			<cfset thisTT = prevTT />

		<cfelse>

			<!---
				We have jumped over a divide in the day (either going
				from AM to PM or PM to AM). Get the current AM/PM by
				swapping the previous one.
			--->
			<cfset thisTT = otherTT( prevTT ) />

		</cfif>

		<!--- Construct the showtime. --->
		<cfset thisTime = (thisHHMM & thisTT) />

		<!---
			Check to see if the actual AM/PM value was provided in
			the raw data. If so, we can compare this known value to
			our assumed value.
		--->
		<cfif (
			len( rawTT ) &&
			(rawTT neq thisTT)
			)>

			<!---
				Our first assumption was wrong. When we are done,
				we will have to swap all of our AM/PM values.
			--->
			<cfset flipAMPM = true />

		</cfif>


	</cfif>


	<!---
		Check to see if we have a rawTT - that is, one of the few
		known AM/PM values. If so, we want to make sure that don't
		ever change this one.

		NOTE: This will only come into play if we need to "flip" the
		AM/PM values.
	--->
	<cfif len( rawTT )>

		<!--- Store the known AM/PM value. --->
		<cfset knownTT[ arrayLen( showtimes ) + 1 ] = rawTT />

	</cfif>


	<!--- Store the previous time properties. --->
	<cfset prevTT = thisTT />
	<cfset prevHHMM = thisHHMM />

	<!--- Add the stored time. --->
	<cfset arrayAppend( showtimes, thisTime ) />


</cfloop>


<!--- Check to see if we need to flip the AM/PM values. --->
<cfif flipAMPM>

	<!--- Loop over each value to swap it. --->
	<cfloop
		index="index"
		from="1"
		to="#arrayLen( showtimes )#"
		step="1">

		<!--- Get the current time parts. --->
		<cfset showtimeParts = reMatchNoCase(
			"\d+:\d+|AM|PM",
			showtimes[ index ]
			) />

		<!---
			Check to see if this index has a known AM/PM value.
			If that is the case, then we don't want to use our own
			logic - we just want to use the original value.
		--->
		<cfif structKeyExists( knownTT, index )>

			<!---
				This is a known value. Use it instead of any AM/PM
				swapping techniques.
			--->
			<cfset showtimes[ index ] = (
				showtimeParts[ 1 ] &
				knownTT[ index ]
				) />

		<cfelse>

			<!---
				This is not a known value - simply reconstruct the
				new time with the swapped AM/PM.
			--->
			<cfset showtimes[ index ] = (
				showtimeParts[ 1 ] &
				otherTT( showtimeParts[ 2 ] )
				) />

		</cfif>

	</cfloop>

</cfif>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!--- Output the original showtimes and our new showtimes. --->
<cfoutput>

	<strong>Original</strong>:

	#lcase( showtimesList )#

	<br />
	<br />

	<strong>Parsed</strong>:

	#lcase( arrayToList( showtimes, " " ) )#

</cfoutput>