Screen-Scraping Movie Showtimes Off Google.com With ColdFusion

<!--- Create an instance of the Google movie component. --->
<cfset google = createObject( "component", "Google" ).init() />

<!---
	Get the theater information for the showtimes at the
	Regal Union Square Stadium 14 theater TODAY.

	ID: 10dd19bd6f57c7c8 - Regal Union Square Stadium 14
	ID: 14c321fe7754e274 - AMC Empire 25

	NOTE: I had to get the theater ID off the website itself.
--->
<cfset theaterInfo = google.getTheaterInfo( "10dd19bd6f57c7c8" ) />


<!--- Output theater information. --->
<cfoutput>

	<p>
		<strong>#theaterInfo.title#</strong><br />
	</p>

	<!---
		Loop over the movies to output the movie titles and
		the times they are showing.
	--->
	<cfloop
		index="movie"
		array="#theaterInfo.movies#">

		<p>
			<strong>#movie.title#</strong><br />
			#arrayToList( movie.showtimes, ", " )#
		</p>

	</cfloop>

</cfoutput>

<cfcomponent
	output="false"
	hint="I help screen scrape the Google Movie showtimes.">


	<cffunction
		name="init"
		access="public"
		returntype="any"
		output="false"
		hint="I return an initialized component.">

		<!--- Define arguments. --->
		<cfargument
			name="baseURL"
			type="string"
			required="false"
			default="http://google.com/movies"
			hint="I am the base URL for the HTTP requests."
			/>

		<!--- Store properties. --->
		<cfset this.baseURL = arguments.baseURL />

		<!--- Return this object reference. --->
		<cfreturn this />
	</cffunction>


	<cffunction
		name="getTheaterInfo"
		access="public"
		returntype="struct"
		output="false"
		hint="I parse the showtimes for the given theater ID.">

		<!--- Define arguments. --->
		<cfargument
			name="theaterID"
			type="string"
			required="true"
			hint="I am the theater ID used by Fandango."
			/>

		<!--- Define the loacl scope. --->
		<cfset var local = {} />

		<!--- Define the theater structure. --->
		<cfset local.theaterInfo = {
			id = arguments.theaterID,
			title = "",
			movies = []
			} />

		<!---
			Grab the HTML off of the Google web page. With Google,
			you typically have to send some sort of User Agent
			because it will block a lot of user agents that it
			considers "bots."
		--->
		<cfhttp
			result="local.googleGet"
			method="get"
			url="#this.baseURL#?tid=#arguments.theaterID#"
			useragent="Mozilla/BenNadel.com"
			/>


		<!---
			While the HTML of the Google page is horrendously
			incomplete, it is thankfully well Classed enough to
			make string parsing somewhat straightfoward.
		--->

		<!--- Grab the theater title div. --->
		<cfset local.theaterDiv = reMatch(
			"<div class=theater>[\w\W]+?</span>",
			local.googleGet.fileContent
			) />

		<!---
			Get the theater title by stripping out all tags from
			the theater DIV. There is an H2 in there somewhere that
			has our theater name.
		--->
		<cfset local.theaterInfo.title = trim(
			reReplace(
				local.theaterDiv[ 1 ],
				"(&nbsp;|</?\w+[^>]*>)",
				" ",
				"all"
				)
			) />


		<!--- Each movie is wrapped in a "movie" DIV that we can
			extract with some regular expression matching.
		--->
		<cfset local.movieDivs = reMatch(
			"<div class=movie>(?:\s|<(\w+)[^>]*>.+?</\1>)+",
			local.googleGet.fileContent
			) />

		<!---
			At this point, we have chunks of strings that contain
			the movie data. Now, we have to loop over each one and
			parse the details.
		--->
		<cfloop
			index="local.movieDiv"
			array="#local.movieDivs#">

			<!--- Parse out the movie name DIV. --->
			<cfset local.nameDiv = reMatch(
				"<div class=name>.+?</div>",
				local.movieDiv
				) />

			<!--- Parse out the showtimes DIV. --->
			<cfset local.showtimesDiv = reMatch(
				"<div class=times>.+?</div>",
				local.movieDiv
				) />

			<!---
				Create a movie struct from the parsed DIVs. For
				this, we are basically going to take the pasred
				DIVs and strip out all tags, leaving just the
				textual data.
			--->
			<cfset local.movie = {
				title = trim(
					reReplace(
						local.nameDiv[ 1 ],
						"</?\w+[^>]*>",
						" ",
						"all"
						)
					),
				showtimes = listToArray(
					reReplace(
						local.showtimesDiv[ 1 ],
						"(&nbsp;|</?\w+[^>]*>)",
						" ",
						"all"
						),
					" "
					)
				} />

			<!--- Append the movie to the ongoing collection. --->
			<cfset arrayAppend(
				local.theaterInfo.movies,
				local.movie
				) />

		</cfloop>

		<!--- Return the result. --->
		<cfreturn local.theaterInfo />
	</cffunction>

</cfcomponent>