Calculating Your Weight Lifting Rep Maximum Using ColdFusion

<cffunction
	name="CalculateRepMaximum"
	access="public"
	returntype="array"
	output="false"
	hint="I calculate estimated repetition maximums based on a given rep max.">

	<!--- Define arguments. --->
	<cfargument
		name="Weight"
		type="numeric"
		required="true"
		hint="I am the weight at which the given rep maximum can be acheived."
		/>

	<cfargument
		name="Reps"
		type="numeric"
		required="false"
		default="1"
		hint="I am the number of maximum reps that can be achieved at the given weight."
		/>

	<!--- Define the local scope. --->
	<cfset var LOCAL = StructNew() />

	<!---
		Create the array that we will return. Each index
		stands for the number of that can be achieved at
		the given weight.
	--->
	<cfset LOCAL.RepMax = ArrayNew( 1 ) />

	<!---
		Create an array to hold the percentage of a 1 rep
		max intensity can be done for a given number of reps.
		This table is an expanded one taken based on the data
		available on BodyBuilding.com.

		This table is just a rough estimate! There is no way that
		true strength can be extrapolated from any given weight
		as your body is trained to be most efficient at any given
		weight. Strength cannot be perfectly extrapolated from
		endurance and vice versa.
	--->
	<cfset LOCAL.Intensity = ArrayNew( 1 ) />
	<cfset LOCAL.Intensity[ 1 ] = 1 />
	<cfset LOCAL.Intensity[ 2 ] = .95 />
	<cfset LOCAL.Intensity[ 3 ] = .9 />
	<cfset LOCAL.Intensity[ 4 ] = .88 />
	<cfset LOCAL.Intensity[ 5 ] = .86 />
	<cfset LOCAL.Intensity[ 6 ] = .83 />
	<cfset LOCAL.Intensity[ 7 ] = .8 />
	<cfset LOCAL.Intensity[ 8 ] = .78 />
	<cfset LOCAL.Intensity[ 9 ] = .76 />
	<cfset LOCAL.Intensity[ 10 ] = .75 />
	<cfset LOCAL.Intensity[ 11 ] = .72 />
	<cfset LOCAL.Intensity[ 12 ] = .7 />

	<!--- Guessing at this point. --->
	<cfset LOCAL.Intensity[ 13 ] = .68 />
	<cfset LOCAL.Intensity[ 14 ] = .66 />
	<cfset LOCAL.Intensity[ 15 ] = .64 />
	<cfset LOCAL.Intensity[ 16 ] = .61 />
	<cfset LOCAL.Intensity[ 17 ] = .58 />
	<cfset LOCAL.Intensity[ 18 ] = .55 />
	<cfset LOCAL.Intensity[ 19 ] = .52 />
	<cfset LOCAL.Intensity[ 20 ] = .48 />


	<!---
		Based on the given weight, calculate the one rep
		maximum using the intensity table.
	--->
	<cfset LOCAL.OneRepMax = Fix( ARGUMENTS.Weight / LOCAL.Intensity[ ARGUMENTS.Reps ] ) />

	<!--- Store the one rep max in our results array. --->
	<cfset LOCAL.RepMax[ 1 ] = LOCAL.OneRepMax />


	<!---
		Now that we have our 1RM in place, we can calculate
		the result set based on the intensity table.
	--->
	<cfloop
		index="LOCAL.Reps"
		from="2"
		to="#ArrayLen( LOCAL.Intensity )#"
		step="1">

		<!--- Set the RM for the given weight. --->
		<cfset LOCAL.RepMax[ LOCAL.Reps ] = Fix( LOCAL.OneRepMax * LOCAL.Intensity[ LOCAL.Reps ] ) />

	</cfloop>


	<!--- Return the populated rep max array. --->
	<cfreturn LOCAL.RepMax />
</cffunction>

<!---
	Get the estimated rep maximums based on being able to
	bench 245 lbs. 2 times on a flat bench.
--->
<cfset arrRM = CalculateRepMaximum( 245, 2 ) />

<!--- Output the estimated rep maximums. --->
<cfloop
	index="intRM"
	from="1"
	to="#ArrayLen( arrRM )#"
	step="1">

	#intRM# RM = #arrRM[ intRM ]# lbs.<br />

</cfloop>