Decoding The EncodeForJavaScript() Output In ColdFusion

<cfscript>

	// COLDFUSION context.
	data = {
		id: 1,
		name: "Kimmie Bo-Bimmie",
		contact: {
			type: "mobile",
			number: "212-555-1199"
		}
	};

</cfscript>
<script type="text/javascript">

	// ColdFusion data being embedded in JAVASCRIPT context.
	console.log(
		JSON.parse( "<cfoutput>#encodeForJavaScript( serializeJson( data ) )#</cfoutput>" )
	);

</script>

<cfscript>

	inputChars = [];

	// I'm going high enough up in the code-point value to make sure we move from the
	// Basic Multilingual Plane (BMP) range into the supplementary characters range (ie,
	// non-fixed width characters).
	for ( i = 0 ; i <= 100000 ; i++ ) {

		inputChars.append( chrFromCodePoint( i ) );

	}

	input = inputChars.toList( "" );
	encoded = encodeForJavaScript( input );
	decoded = decodeForJavaScript( encoded ); // My custom function for decoding.

	// Did we successfully decode the encoded JavaScript value.
	writeDump( input == decoded );

	// For debugging.
	// writeDump( input );
	// writeDump( encoded );
	// writeDump( decoded );

	// ------------------------------------------------------------------------------- //
	// ------------------------------------------------------------------------------- //

	/**
	* I decode the given JavaScript-encoded value.
	*/
	public string function decodeForJavaScript( required string input ) {

		// When encoding for JavaScript, each of the special characters appears to be
		// encoded using using hexadecimal format with either a 2-digit notation (\xHH) or
		// a 4-digit notation (\uHHHH). We can create a RegEx pattern that looks for both
		// encodings, capturing each in a different group.
		var decodedInput = jreReplaceAllQuoted(
			input,
			"(?i)\\x([0-9a-f]{2})|\\u([0-9a-f]{4})",
			( $0, $1, $2 ) => {

				var codePoint = $1.len()
					? $1 // Hex encoding.
					: $2 // Unicode encoding.
				;

				return chrFromCodePoint( inputBaseN( codePoint, 16 ) );

			}
		);

		return decodedInput;

	}


	/**
	* I replace all of the pattern matches in the given input with the result of the given
	* operator function. The replacements are quoted (ie, cannot consume back-references).
	*/
	public string function jreReplaceAllQuoted(
		required string input,
		required string pattern,
		required function operator
		) {

		var matcher = createObject( "java", "java.util.regex.Pattern" )
			.compile( pattern )
			.matcher( input )
		;
		var buffer = createObject( "java", "java.lang.StringBuffer" )
			.init()
		;

		while ( matcher.find() ) {

			var args = [ matcher.group() ];

			for ( var i = 1 ; i <= matcher.groupCount() ; i++ ) {

				// NOTE: If I try to combine the .group() call with the fallback (?:)
				// operator, it always results in an empty string. As such, I need to
				// break the reading of the value into its own line. I believe this is a
				// known bug in the Elvis operator implementation.
				var groupValue = matcher.group( javaCast( "int", i ) );
				args.append( groupValue ?: "" );

			}

			matcher.appendReplacement(
				buffer,
				matcher.quoteReplacement( operator( argumentCollection = args ) )
			);

		}

		matcher.appendTail( buffer );

		return buffer.toString();

	}


	/**
	* I return the String corresponding to the given codePoint. If the codePoint is
	* outside the Basic Multilingual Plane (BMP) range (ie, above 65535), then the
	* resultant string may contain multiple "characters".
	*/
	public string function chrFromCodePoint( required numeric codePoint ) {

		// The in-built chr() function can handle code-point values up to 65535 (these
		// are characters in the fixed-width 16-bit range, sometimes referred to as the
		// Basic Multilingual Plane (BMP) range). After 65535, we are dealing with
		// supplementary characters that require more than 16-bits. For that, we have to
		// drop down into the Java layer.
		if ( codePoint <= 65535 ) {

			return chr( codePoint );

		}

		// Since we are outside the Basic Multilingual Plane (BMP) range, the resulting
		// array should contain the surrogate pair (ie, multiple characters) required to
		// represent the supplementary Unicode value.
		var chars = createObject( "java", "java.lang.Character" )
			.toChars( val( codePoint ) )
		;

		return arrayToList( chars, "" );

	}

</cfscript>