Generating The Content-MD5 Checksum For The Amazon S3 REST API Using ColdFusion

<cfscript>


	// I generate the Amazon S3 request authentication signature using
	// the given secret key and the given input.
	string function generateSignature(
		required string key,
		required string input
		) {

		// Create the specification for our secret key.
		var secretkeySpec = createObject( "java", "javax.crypto.spec.SecretKeySpec" ).init(
			charsetDecode( key, "utf-8" ),
			javaCast( "string", "HmacSHA1" )
		);

		// Get an instance of our MAC generator.
		var mac = createObject( "java", "javax.crypto.Mac" ).getInstance(
			javaCast( "string", "HmacSHA1" )
		);

		// Initialize the Mac with our secret key spec.
		mac.init( secretkeySpec );

		// Hash the input (as a byte array).
		var hashedBytes = mac.doFinal(
			charsetDecode( input, "utf-8" )
		);

		// Return the hashed bytes as Base64.
		return(
			binaryEncode( hashedBytes, "base64" )
		);

	}


	// I generate the Amazon S3 request authentication signature using
	// the new hmac() function found in ColdFusion 10.
	string function generateSignatureWithColdFusion10(
		required string key,
		required string input
		) {

		// Unfortunateyl, it looks like the hmac() function can only
		// return values in HEX. As such, we'll have to convert it
		// from hex to binary, and then encode the binary as Base64.
		var hexEncoding = hmac( input, key, "HmacSHA1", "utf-8" );

		return(
			binaryEncode(
				binaryDecode( hexEncoding, "hex" ),
				"base64"
			)
		);

	}


	// ------------------------------------------------------ //
	// ------------------------------------------------------ //


	// I generate the base64-encoded 128-bit MD5 digest of the
	// message content that is being posted to Amazon S3.
	string function generateContentMD5( required any content ) {

		// Get our instance of the digest algorithm.
		var messageDigest = createObject( "java", "java.security.MessageDigest" )
			.getInstance( javaCast( "string", "MD5" ) )
		;

		// Create the MD5 hash (as a byte array).
		var digest = messageDigest.digest( content );

		// Return the hashed bytes as Base64.
		return(
			binaryEncode( digest, "base64" )
		);

	}


	// I generate the base64-encoded 128-bit MD5 digest of the
	// message content using the new hash() functionality present
	// in ColdFusion 10.
	string function generateContentMD5WithColdFusion10( required any content ) {

		// Unfortunateyl, it looks like the hash() function can only
		// return values in HEX. As such, we'll have to convert it
		// from hex to binary, and then encode the binary as Base64.
		var hexEncoding = hash( content, "MD5", "utf-8" );

		return(
			binaryEncode(
				binaryDecode( hexEncoding, "hex" ),
				"base64"
			)
		);

	}


	// ------------------------------------------------------ //
	// ------------------------------------------------------ //
	// ------------------------------------------------------ //
	// ------------------------------------------------------ //


	// Includ our Amazon S3 crendentials (for testing).
	include "../credentials.cfm";

	// Read in the file that we are going to post up to Amazon S3.
	// This will be the BODY of our PUT and the basis for our
	// Content-MD5 generation.
	content = fileReadBinary( expandPath( "./helena.jpg" ) );

	// The target resource for our upload to Amazon S3.
	resource = "/testing.bennadel.com/signed-urls/helena.jpg";

	// Get the current HTTP date - requied for all Amazon S3 requests.
	currentTime = getHttpTimeString( now() );

	// Generate the Base64-encoded Content-MD5 value.
	contentMD5 = generateContentMD5WithColdFusion10( content );

	// The content-type will be stored as meta-data with the S3
	// resource and then will be used to serve up the resource later.
	contentType = "image/jpeg";

	// Set up the part of the string to sign.
	stringToSignParts = [
		"PUT",
		contentMD5,
		contentType,
		currentTime,
		resource
	];

	// Generate the Base64-encoded signature.
	signature = generateSignatureWithColdFusion10(
		aws.secretKey,
		arrayToList( stringToSignParts, chr( 10 ) )
	);


	// ------------------------------------------------------ //
	// ------------------------------------------------------ //


	// Set up our Amazon S3 RESTful API request.
	put = new Http(
		method = "put",
		url = "https://s3.amazonaws.com#resource#"
	);

	put.addParam(
		type = "header",
		name = "Authorization",
		value ="AWS #aws.accessID#:#signature#"
	);

	put.addParam(
		type ="header",
		name ="Content-Length",
		value = arrayLen( content )
	);

	put.addParam(
		type = "header",
		name = "Content-MD5",
		value = contentMD5
	);

	put.addParam(
		type = "header",
		name = "Content-Type",
		value = contentType
	);

	put.addParam(
		type = "header",
		name = "Date",
		value = currentTime
	);

	put.addParam(
		type = "body",
		value = content
	);

	// Make the acutal request and get the result.
	result = put.send().getPrefix();


	// Output the status code.
	writeOutput( "Status: " & result.statusCode );


</cfscript>