Generating CRC-32 And Adler-32 Checksums In ColdFusion

<cfscript>

	/**
	* I compute the Adler-32 checksum for the given string. (From the Java docs) An
	* Adler-32 checksum is almost as reliable as a CRC-32 but can be computed much
	* faster.
	*
	* @input I am the input being checked.
	* @output false
	*/
	public numeric function adler32( required string input ) {

		var checksum = createObject( "java", "java.util.zip.Adler32" ).init();

		checksum.update( charsetDecode( input, "utf-8" ) );

		return( checksum.getValue() );

	}


	/**
	* I compute the CRC-32 checksum for the given string.
	*
	* @input I am the input being checked.
	* @output false
	*/
	public numeric function crc32( required string input ) {

		var checksum = createObject( "java", "java.util.zip.CRC32" ).init();

		checksum.update( charsetDecode( input, "utf-8" ) );

		return( checksum.getValue() );

	}


	// ------------------------------------------------------------------------------- //
	// ------------------------------------------------------------------------------- //


	// Let's test the CRC-32 and Adler-32 algorithms over a few different inputs.
	inputs = [
		"",
		123,
		"ben@testing.com.edu",
		"I'm a cybernetic organism. Living tissue over a metal endoskeleton.",
		"In three years, Cyberdyne will become the largest supplier of military
			computer systems. All stealth bombers are upgraded with Cyberdyne
			computers, becoming fully unmanned. Afterwards, they fly with a
			perfect operational record. The Skynet Funding Bill is passed. The
			system goes online on August 4th, 1997. Human decisions are removed
			from strategic defense. Skynet begins to learn at a geometric rate.
			It becomes self-aware 2:14 AM, Eastern time, August 29th. In a panic,
			they try to pull the plug."
	];

</cfscript>

<cfoutput>

	<h2>
		Using CRC-32
	</h2>

	<cfloop index="input" array="#inputs#">

		<!--- Output twice to test repeatability. --->
		#left( input, 30 )# ... #crc32( input )#<br />
		#left( input, 30 )# ... #crc32( input )#<br />

	</cfloop>


	<h2>
		Using Adler-32
	</h2>

	<cfloop index="input" array="#inputs#">

		<!--- Output twice to test repeatability. --->
		#left( input, 30 )# ... #adler32( input )#<br />
		#left( input, 30 )# ... #adler32( input )#<br />

	</cfloop>

</cfoutput>