Printing To The Primary Output Stream From Within A ColdFusion CFThread Tag

<!---
	Check to see if we are running in the end mode of the tag.
	That is the only mode where we will have a page context to
	work with.
--->
<cfif (thisTag.executionMode eq "end")>

	<!---
		Param the page context. This is the context that contains
		the output buffer to which we are writing.
	--->
	<cfparam
		name="attributes.pageContext"
		type="any"
		/>

	<!--- Get the response object. --->
	<cfset response = attributes.pageContext.getResponse() />

	<!--- Get the character-based output stream. --->
	<cfset outputStream = response.getOutputStream() />

	<!---
		Print the generated content of this custom tag to the
		given output stream.
	--->
	<cfset outputStream.print(
		javaCast( "string", thisTag.generatedContent )
		) />

	<!---
		Clear the generated content so that we aren't printing it
		to two different output buffers.
	--->
	<cfset thisTag.generatedContent = "" />

</cfif>

<!---
	Get a reference to the parent page context. This will be the
	context to which our CFThread instances will print. Since each
	CFThread shares the Variables scope with the spawning context,
	this variable will be available without needed a deep-copy (ie.
	without passing via the CFThread tag attributes).
--->
<cfset rootPageContext = getPageContext() />


<!---
	Build an array of image URLs to download (we don't care about
	the images, we just want something that will take a while to
	process).
--->
<cfset imageUrls = [
	"http://farm4.static.flickr.com/3191/2395355756_507b1940e4_b.jpg",
	"http://farm3.static.flickr.com/2289/2395352122_65a666429f_b.jpg",
	"http://farm4.static.flickr.com/3022/2394516701_bf4eccee3b_b.jpg",
	"http://farm4.static.flickr.com/3227/2395350024_778bd01df7_b.jpg",
	"http://farm3.static.flickr.com/2168/2394514421_25c4483573_b.jpg",
	"http://farm3.static.flickr.com/2303/2395347746_97c2814944_b.jpg",
	"http://farm4.static.flickr.com/3214/2395343244_7795c8de09_b.jpg",
	"http://farm4.static.flickr.com/3022/2395368874_18fa5f189f_b.jpg",
	"http://farm4.static.flickr.com/3017/2395367726_bd0c99f397_b.jpg",
	"http://farm4.static.flickr.com/3280/2394532393_99a0545761_b.jpg",
	"http://farm3.static.flickr.com/2179/2395365392_b1e9c5a45c_b.jpg",
	"http://farm3.static.flickr.com/2117/2394527499_5b7e704b9c_b.jpg",
	"http://farm4.static.flickr.com/3267/2395360732_7bc0266c0b_b.jpg",
	"http://farm3.static.flickr.com/2241/2395359786_dc8006f0f8_b.jpg",
	"http://farm3.static.flickr.com/2130/2394524263_a22f7e3732_b.jpg",
	"http://farm4.static.flickr.com/3189/2395329372_718e759834_z.jpg"
	] />


<!--- Define the path to which we are going to save the images. --->
<cfset imagesDirectory = expandPath( "./images/" ) />


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!---
	Now, let's launch a thread that downloads all of the images to
	the local file system. After each image, the thread is going to
	print to the root page output.
--->
<cfthread
	name="threadA"
	action="run">

	<!--- Loop over the array to download each image. --->
	<cfloop
		index="index"
		from="1"
		to="#arrayLen( imageUrls )#"
		step="1">

		<!--- Download the image binary. --->
		<cfhttp
			result="imageGet"
			method="get"
			url="#imageUrls[ index ]#"
			getasbinary="auto"
			/>

		<!--- Save the image binary. --->
		<cffile
			action="write"
			output="#imageGet.fileContent#"
			file="#imagesDirectory#A_#index#.jpg"
			/>

		<!---
			Write the feedback to the root output. Notice that we
			are passing in a reference to the page context of the
			root page, NOT the CFThread.
		--->
		<cf_output pagecontext="#rootPageContext#">
			<cfoutput>

				Downloaded Thread A - #index#<br />

			</cfoutput>
		</cf_output>

	</cfloop>

</cfthread>


<!---
	Now, let's launch another thread that does the exact same thing
	as the first thread. This is just to show the parallal nature of
	multiple threads all writing to the same output.
--->
<cfthread
	name="threadB"
	action="run">

	<!--- Loop over the array to download each image. --->
	<cfloop
		index="index"
		from="1"
		to="#arrayLen( imageUrls )#"
		step="1">

		<!--- Download the image binary. --->
		<cfhttp
			result="imageGet"
			method="get"
			url="#imageUrls[ index ]#"
			getasbinary="auto"
			/>

		<!--- Save the image binary. --->
		<cffile
			action="write"
			output="#imageGet.fileContent#"
			file="#imagesDirectory#B_#index#.jpg"
			/>

		<!---
			Write the feedback to the root output. Notice that we
			are passing in a reference to the page context of the
			root page, NOT the CFThread.
		--->
		<cf_output pagecontext="#rootPageContext#">
			<cfoutput>

				Downloaded Thread B - #index#<br />

			</cfoutput>
		</cf_output>

	</cfloop>

</cfthread>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!--- Flag that the threads are not done yet. --->
<cfset isThreadsProcessing = true />

<!---
	Keep looping until the threads are done. We could use a JOIN to
	wait for the parallel threads to finish; however, that would
	pause the output of the parent thread and we would not get any
	real-time feedback.
--->
<cfloop condition="isThreadsProcessing">


	Downloading...<br />

	<!---
		Flush any output generated be either this page or one of
		the threads.
	--->
	<cfflush interval="1" />

	<!--- Check to see if the threads are done. --->
	<cfset isThreadsProcessing = !(
		listFindNoCase( "completed,terminated", cfthread.threadA.status ) &&
		listFindNoCase( "completed,terminated", cfthread.threadB.status )
		) />

	<!---
		If the threads are still processing, then sleep the parent
		page for a bit. That will give the parallel threads time to
		make some progress and write to the parent page's output
		buffer.
	--->
	<cfif isThreadsProcessing>

		<!--- Sleep the parent page briefly. --->
		<cfthread
			action="sleep"
			duration="500"
			/>

	</cfif>


</cfloop>


Done downloading!<br />