ColdFusion CFThread Body Context Exploration

After my last post on checking session existence inside of ColdFusion CFThread tags, I became curious as to what else can be done inside of a CFThread tag body. To experiment, I put this little page together that launches two "synchronous" asynchronous threads and then dumps out their data structures. I say "synchronous" only because I wait for them to rejoin the current page request:

<!---
	Put in page title to make sure this content does
	not get cleared from buffer.
--->
<h1>
	ColdFusion 8 CFThread Testing
</h1>



<!--- Launch asynchronous thread. --->
<cfthread
	action="run"
	name="thread1">

	<h2>
		CFThread 1 Body Content
	</h2>

	<p>
		This is coming from thread 1.
	</p>

</cfthread>


<!--- Wait for thread 1 to re-join current page. --->
<cfthread
	action="join"
	name="thread1"
	/>

<!--- Dump out thread content. --->
<cfdump
	var="#CFTHREAD.Thread1#"
	label="Thread1 Data"
	/>



<!--- Sleep for 2 second between the two threads. --->
<cfthread
	action="sleep"
	duration="#(2 * 1000)#"
	/>



<!--- Launch asynchronous thread. --->
<cfthread
	action="run"
	name="thread2">

	<h2>
		CFThread 2 Body Content
	</h2>

	<p>
		This is coming from thread 2.
	</p>

	<!--- Clear content. --->
	<cfcontent reset="true" />

	<!--- Store the start time of the current page context. --->
	<cfset THREAD.ContextStartTime =
		GetPageContext().GetFusionContext().GetStartTime()
		/>

</cfthread>


<!--- Wait for thread 2 to re-join current page. --->
<cfthread
	action="join"
	name="thread2"
	/>

<!--- Dump out thread content. --->
<cfdump
	var="#CFTHREAD.Thread2#"
	label="Thread2 Data"
	/>

The first thread executes with some body content and then we wait for it to return and dump out. Nothing special going on there at all. This is the CFDump output that we get from the first thread:

It contains the HTML content of the tag and the additional thread data tidbits.

Then, our page sleeps for two seconds and launches a second CFThread tag. Inside this thread, we have some interesting things going on. First, we call a CFContent tag to reset the content buffer. I have never done this in anything but the primary page, so I wasn't even sure if this would compile. Then, I grab the page context within the CFThread and store that page start time and store it in the THREAD scope.

This is the CFDump output of the second thread:

So, we got some interesting stuff going on here. For starters, the OUTPUT of the tag is empty. This means that the CFContent[reset=true] cleared the output buffer of the CFThread tag. The h1 tag of our original page request was left intact, so we know that this reset action was limited to the CFThread tag. Second, the ContextStartTime variable that we stored into the THREAD scope is:

{ts '2007-12-12 09:26:04'}

... is the same start time as denoted by the inherent Thread data, which is two seconds after the start time of the first thread. What this is demonstrating is that the body of a CFThread tag runs entirely in its own context much like an individual ColdFusion request (and somewhat like an individual template). I am sure that this makes sense when you know how threads work, but for me, this is interesting news.

Want to use code from this post? Check out the license.

Short link: https://bennadel.com/1082