ColdFusion 8 ImageDrawTextArea() (Inspired By Barney Boisvert!)

<!--- Draw the text area on the image object. --->
<cfset ImageDrawTextArea(
	imgCanvas,
	"If you think flattery will get you anywhere with me, well... that's where you're right.",
	50,
	50,
	400,
	objAttributes
	) />

<!--- Write the image to the browser. --->
<cfimage
	action="writetobrowser"
	source="#imgCanvas#"
	/>

<cffunction
	name="ImageDrawTextArea"
	access="public"
	returntype="void"
	output="true"
	hint="Draws a text area on the given canvas.">

	<cfargument
		name="Source"
		type="any"
		required="true"
		hint="The image on which we are going to write the text."
		/>

	<cfargument
		name="Text"
		type="string"
		required="true"
		hint="The text value that we are going to write."
		/>

	<cfargument
		name="X"
		type="numeric"
		required="true"
		hint="The X coordinate of the start of the text."
		/>

	<cfargument
		name="Y"
		type="numeric"
		required="true"
		hint="The Y coordinate of the baseline of the start of the text."
		/>

	<cfargument
		name="Width"
		type="numeric"
		required="true"
		hint="The width of the text area in which the text should fit."
		/>

	<cfargument
		name="Attributes"
		type="struct"
		required="false"
		default="#StructNew()#"
		hint="The attributes of the font (including TextAlign and LineHeight)."
		/>


	<!--- Define the local scope. --->
	<cfset var LOCAL = {} />


	<!---
		From the ColdFusion image, get the underlying Java AWT
		object. This will allow us access to properties that
		we will need to space and style the font.
	--->
	<cfset LOCAL.Graphics = ImageGetBufferedImage( ARGUMENTS.Source ).GetGraphics() />

	<!---
		Get the font that is currently set in the image. From
		this, we will be able to default the properties of our
		text attributes.
	--->
	<cfset LOCAL.CurrentFont = LOCAL.Graphics.GetFont() />


	<!---
		Now, we are going to check to see if the passed in
		attributes has all the properties that we need to
		properly render the new font. If it does not, then we
		are gonna default that attribute to what is in the
		current font of the graphic.
	--->


	<!--- Check for a defined size.--->
	<cfif NOT StructKeyExists( ARGUMENTS.Attributes, "Size" )>

		<!--- Get size from current font. --->
		<cfset ARGUMENTS.Attributes.Size = LOCAL.CurrentFont.GetSize() />

	</cfif>


	<!--- Check for a defined font. --->
	<cfif NOT StructKeyExists( ARGUMENTS.Attributes, "Font" )>

		<cfset ARGUMENTS.Attributes.Font = LOCAL.CurrentFont.GetFontName() />

	</cfif>


	<!--- Check for a defined style. --->
	<cfif NOT StructKeyExists( ARGUMENTS.Attributes, "Style" )>

		<!---
			When it comes to defaulting the style, we need to
			build not only the font attributes, but also the
			font style argument for creating our new font (for
			the Font Metrics). Because of that, we will be
			building a bit-mask for the style.

			Because the Styles are just constants, we can pull
			them out of our Current Font object.
		--->
		<cfif (
			LOCAL.CurrentFont.IsBold() AND
			LOCAL.CurrentFont.IsItalic()
			)>

			<!--- Set the style. --->
			<cfset ARGUMENTS.Attributes.Style = "bolditalic" />

			<!--- Set the bit mask. --->
			<cfset LOCAL.FontStyleMask = BitOR(
				LOCAL.CurrentFont.BOLD,
				LOCAL.CurrentFont.ITALIC
				) />

		<cfelseif LOCAL.CurrentFont.IsBold()>

			<!--- Set the style. --->
			<cfset ARGUMENTS.Attributes.Style = "bold" />

			<!--- Set the bit mask. --->
			<cfset LOCAL.FontStyleMask = LOCAL.CurrentFont.BOLD />

		<cfelseif LOCAL.CurrentFont.IsItalic()>

			<!--- Set the style. --->
			<cfset ARGUMENTS.Attributes.Style = "italic" />

			<!--- Set the bit mask. --->
			<cfset LOCAL.FontStyleMask = LOCAL.CurrentFont.ITALIC />

		<cfelse>

			<!--- Set the style. --->
			<cfset ARGUMENTS.Attributes.Style = "plain" />

			<!--- Set the bit mask. --->
			<cfset LOCAL.FontStyleMask = LOCAL.CurrentFont.PLAIN />

		</cfif>

	<cfelse>

		<!--- Set the plain font mask. --->
		<cfset LOCAL.FontStyleMask = LOCAL.CurrentFont.PLAIN />

	</cfif>


	<!---
		Now that we have our Font attributes all paramed, we
		need to create a new Font object (that will be used to
		get the Font Metrics for the user's text).
	--->
	<cfset LOCAL.NewFont = CreateObject(
		"java",
		"java.awt.Font"
		).Init(
			JavaCast( "string", ARGUMENTS.Attributes.Font ),
			JavaCast( "int", LOCAL.FontStyleMask ),
			JavaCast( "int", ARGUMENTS.Attributes.Size )
			)
		/>


	<!---
		ASSERT: At this point, we have paramed the
		font attributes that are required for a
		normal ImageDrawText() call.
	--->


	<!---
		In additional the standard attributes defined above,
		this function allows for a few additional font
		attributes. Let's give them some default values.
	--->
	<cfparam
		name="ARGUMENTS.Attributes.LineHeight"
		type="numeric"
		default="#(1.4 * ARGUMENTS.Attributes.Size)#"
		/>

	<cfparam
		name="ARGUMENTS.Attributes.TextAlign"
		type="string"
		default="left"
		/>



	<!---
		Now that we have our new Font set up, get the
		Font Metrics for our graphic in the context of
		the new Font.
	--->
	<cfset LOCAL.FontMetrics = LOCAL.Graphics.GetFontMetrics(
		LOCAL.NewFont
		) />


	<!---
		Now, that we have our font-testing environment set up,
		it's time to start figuring out how we are gonna layout
		the text. To begin, we are going to take the user's text
		and split it up into an array of word tokens (based on
		single spaces).
	--->
	<cfset LOCAL.Words = ARGUMENTS.Text.Split(
		JavaCast( "string", " " )
		) />

	<!---
		As we loop through the words, we are going to keep
		track of which words fit onto each line and the
		dimensions that that line occupies. To store this, we
		will use an array of Line structures.
	--->
	<cfset LOCAL.Lines = [] />

	<!---
		Create the first line item. Here, the Text is the
		string data for the line and the Width / Height are
		the physical dimensions of the text.
	--->
	<cfset LOCAL.Lines[ 1 ] = {
		Text = "",
		Width = 0,
		Height = 0
		} />


	<!--- Loop over all the words. --->
	<cfloop
		index="LOCAL.WordIndex"
		from="1"
		to="#ArrayLen( LOCAL.Words )#"
		step="1">

		<!--- Get a short hand to the current word. --->
		<cfset LOCAL.Word = LOCAL.Words[ LOCAL.WordIndex ] />

		<!--- Get a short hand to the current line. --->
		<cfset LOCAL.Line = LOCAL.Lines[ ArrayLen( LOCAL.Lines ) ] />


		<!---
			Using the Font Metrics, get the bounds of the
			current text line with the addition of the next
			word.
		--->
		<cfset LOCAL.TextBounds = LOCAL.FontMetrics.GetStringBounds(
			JavaCast(
				"string",
				Trim( LOCAL.Line.Text & " " & LOCAL.Word )
				),
			LOCAL.Graphics
			) />


		<!---
			Now that we have the physical dimensions, we need to
			check to see if new line would be too wide for the
			text area. If it is too wide and there is not text
			on the line yet, then add it anyway as it simply is
			too wide for the text area.
		--->
		<cfif (
			(LOCAL.TextBounds.GetWidth() LTE ARGUMENTS.Width) OR
			(NOT Len( LOCAL.Line.Text ))
			)>

			<!---
				The current word will fit on the current line
				so add it to the string data of the line. If
				this is NOT the first word, be sure to add a
				preceeding space.
			--->
			<cfset LOCAL.Line.Text &= (
				IIF(
					Len( LOCAL.Line.Text ),
					DE( " " ),
					DE( "" )
					) &
				LOCAL.Word
				) />

			<!---
				Since the text data of this line has been
				updated, we need to get the updated dimensions
				of the line. When it comes go getting the width,
				we have to be careful about lines that are too
				wide for the text area. We never want to record
				any width that is larger than the text area.
			--->
			<cfset LOCAL.Line.Width = Min(
				LOCAL.TextBounds.GetWidth(),
				ARGUMENTS.Width
				) />

			<!--- Get height. --->
			<cfset LOCAL.Line.Height = LOCAL.TextBounds.GetHeight() />

		<cfelse>

			<!---
				Due to the dimensions of the potential line, we
				are going to have to move the current word to a
				new line. For this we must create a new line
				object and insert the word.
			--->

			<!---
				Get the bounds of the new line (which will be
				the same as the bounds of the current word).
			--->
			<cfset LOCAL.TextBounds = LOCAL.FontMetrics.GetStringBounds(
				JavaCast( "string", LOCAL.Word ),
				LOCAL.Graphics
				) />

			<!--- Create a new line object. --->
			<cfset LOCAL.Line = {
				Text = LOCAL.Word,
				Width = LOCAL.TextBounds.GetWidth(),
				Height = LOCAL.TextBounds.GetHeight()
				} />

			<!--- Append the new line object to our array. --->
			<cfset ArrayAppend(
				LOCAL.Lines,
				LOCAL.Line
				) />

		</cfif>

	</cfloop>


	<!---
		ASSERT: At this point, we have determined which text
		will go on which lines of our rendered text area. We
		also know the dimensions of each line of text.
	--->


	<!---
		Now, it's time to actually draw the text on the passed
		in image object. Loop over the lines array.
	--->
	<cfloop
		index="LOCAL.LineIndex"
		from="1"
		to="#ArrayLen( LOCAL.Lines )#"
		step="1">

		<!--- Get a shorthand to the current line object. --->
		<cfset LOCAL.Line = LOCAL.Lines[ LOCAL.LineIndex ] />


		<!---
			Let's determine the X-coordinate of this line of
			text. This will depend on the alignment of the text
			(left, center, right).
		--->
		<cfswitch expression="#ARGUMENTS.Attributes.TextAlign#">

			<!--- Right aligned text. --->
			<cfcase value="right">

				<cfset LOCAL.X = (
					ARGUMENTS.X +
					ARGUMENTS.Width -
					LOCAL.Line.Width
					) />

			</cfcase>

			<!--- Center align text. --->
			<cfcase value="center">

				<cfset LOCAL.X = (
					ARGUMENTS.X +
					Fix(
						(ARGUMENTS.Width - LOCAL.Line.Width) /
						2
					)) />

			</cfcase>

			<!--- Left aligned text. --->
			<cfdefaultcase>

				<cfset LOCAL.X = ARGUMENTS.X />

			</cfdefaultcase>
		</cfswitch>


		<!---
			When getting the Y value of the line, we have to
			take into account line height and count of the
			current line. This is for the baseline of the text,
			NOT the top-left-most corner.
		--->
		<cfset LOCAL.Y = (
			ARGUMENTS.Y +
			(
				(LOCAL.LineIndex - 1) *
				ARGUMENTS.Attributes.LineHeight
			)) />



		<!---
			Draw the text at the given coordinates. Pass in
			the structure that we got. This Attributes structure
			will contain extraneous information (TextAlign,
			LineHeight), but this will not throw an error.
		--->
		<cfset ImageDrawText(
			ARGUMENTS.Source,
			LOCAL.Line.Text,
			LOCAL.X,
			LOCAL.Y,
			ARGUMENTS.Attributes
			) />

	</cfloop>


	<!--- Return out. --->
	<cfreturn />
</cffunction>

<!--- Kill extra output. --->
<cfsilent>

	<!--- Param the form values. --->
	<cfparam
		name="FORM.font"
		type="string"
		default="courier new"
		/>

	<cfparam
		name="FORM.size"
		type="numeric"
		default="24"
		/>

	<cfparam
		name="FORM.text_align"
		type="string"
		default="right"
		/>

	<cfparam
		name="FORM.line_height"
		type="numeric"
		default="#Fix(FORM.size * 1.5)#"
		/>

	<cfparam
		name="FORM.text"
		type="string"
		default="I hope this doesn't come off as offensive, but seeing you in that dress will most definately be the highlight of my day."
		/>

	<cfparam
		name="FORM.width"
		type="numeric"
		default="400"
		/>

</cfsilent>

<cfoutput>

	<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
	<html>
	<head>
		<title>ImageDrawTextArea() ColdFusion 8 Demo</title>

		<style type="text/css">

			body {
				font-family: verdana ;
				font-size: 62.5% ;
				}

			p {
				clear: both ;
				font-size: 1.2em ;
				}

			label {
				float: left ;
				font-weight: bold ;
				width: 120px ;
				}

			input,
			select {
				width: 400px ;
				}

		</style>
	</head>
	<body>

		<h1>
			ImageDrawTextArea() ColdFusion 8 Demo
		</h1>

		<form action="#CGI.script_name#" method="post">

			<p>
				<label>Font:</label>

				<select name="font">
					<cfloop
						index="strFont"
						list="verdana,arial,courier new,georgia"
						delimiters=",">

						<option value="#strFont#"
							<cfif (FORM.font EQ strFont)>
								selected="true"
							</cfif>
							>#strFont#</option>
					</cfloop>
				</select>
			</p>

			<p>
				<label>Size:</label>

				<select name="size">
					<cfloop
						index="intSize"
						from="8"
						to="40"
						step="1">

						<option value="#intSize#"
							<cfif (FORM.size EQ intSize)>
								selected="true"
							</cfif>
							>#intSize#</option>
					</cfloop>
				</select>
			</p>

			<p>
				<label>Align:</label>

				<select name="text_align">
					<cfloop
						index="strAlign"
						list="left,center,right"
						delimiters=",">

						<option value="#strAlign#"
							<cfif (FORM.text_align EQ strAlign)>
								selected="true"
							</cfif>
							>#strAlign#</option>
					</cfloop>
				</select>
			</p>

			<p>
				<label>Line Height:</label>

				<select name="line_height">
					<cfloop
						index="intHeight"
						from="10"
						to="50"
						step="1">

						<option value="#intHeight#"
							<cfif (FORM.line_height EQ intHeight)>
								selected="true"
							</cfif>
							>#intHeight#</option>
					</cfloop>
				</select>
			</p>

			<p>
				<label>Text:</label>

				<input type="text" name="text" value="#HtmlEditFormat( FORM.text )#" />
			</p>

			<p>
				<label>Textarea Width:</label>

				<select name="width">
					<cfloop
						index="intWidth"
						list="100,200,300,400,500"
						delimiters=",">

						<option value="#intWidth#"
							<cfif (FORM.width EQ intWidth)>
								selected="true"
							</cfif>
							>#intWidth#</option>
					</cfloop>
				</select>
			</p>

			<p>
				<button type="submit">
					Generate Image &raquo;
				</button>
			</p>

		</form>


		<h2>
			Rendered Image and Text Area
		</h2>


		<!--- Create a new canvas. --->
		<cfset imgCanvas = ImageNew( "", 545, 350, "rgb" ) />

		<!--- Set up the font attributes. --->
		<cfset objAttributes = {
			Font = FORM.font,
			Size = FORM.size,
			TextAlign = FORM.text_align,
			LineHeight = FORM.line_height
			} />

		<!--- Turn on anti-aliasing for nicer rendering. --->
		<cfset ImageSetAntialiasing(
			imgCanvas,
			"on"
			) />

		<!--- Draw the text area on the image object. --->
		<cfset ImageDrawTextArea(
			imgCanvas,
			FORM.text,
			50,
			50,
			FORM.width,
			objAttributes
			) />

		<!--- Write the image to the browser. --->
		<cfimage
			action="writetobrowser"
			source="#imgCanvas#"
			/>
 

	</body>
	</html>

</cfoutput>