Ask Ben: Forward ColdFusion Requests To Another Domain

<!--- Get the request object for the current page. --->
<cfset objRequest = GetPageContext().GetRequest() />

<!---
	Get the requested URL string buffer (this will NOT
	contain the query string).
--->
<cfset objURLBuffer = objRequest.GetRequestURL() />

<!--- Get the query string for the current request. --->
<cfset strQueryString = objRequest.GetQueryString() />


<!---
	Append the query string to the URL buffer if one exists
	for the current request. If no query string was present,
	the GetQueryString() method call will return NULL.
--->
<cfif StructKeyExists( VARIABLES, "strQueryString" )>

	<cfset objURLBuffer.Append( "?" & strQueryString ) />

</cfif>


<!---
	ASSERT: At this point, our URL string buffer holds the
	full URL of the page that is currently being requested.
	Now that we have that, we need to forward users to
	another domain.
--->


<!--- Convert the URL buffer to a string. --->
<cfset strURL = objURLBuffer.ToString() />

<!---
	Instead of just blindly replacing domain values, make
	sure that it exists (if for some reason, something goes
	wrong, you might create an infinite loop of forwarding
	(if the domain never changes).

	CAUTION: I am using a regular expression here in case
	you want to hanlde thinks like www or what not. If you
	don't care about that, just use FindNoCase() and remove
	the \b constructs.
--->
<cfif REFindNoCase( "\bOLD_DOMAIN\b", strURL )>

	<!---
		We found the OLD domain in the current URL. Now,
		let's replace it with the NEW domain.

		CAUTION: I am using regular expression here in case
		you want to handle things differently. If you don't
		care about RegEx, just use a ReplaceNoCase() instead.
	--->
	<cfset strNewURL = strURL.ReplaceFirst(
		"\bswoop\b",
		"NEW_DOMAIN"
		) />

	<!--- Return the permanent redirect to new URL. --->
	<cfheader
		statuscode="301"
		statustext="Moved Permanently"
		/>

	<!--- Return new URL. --->
	<cfheader
		name="Location"
		value="#strNewURL#"
		/>


<cfelse>


	<!---
		Something went wrong with our code and we are not
		finding the old domain. Return a 500 error.
	--->
	<cfheader
		statuscode="500"
		statustext="Internal Server Error"
		/>

	<!--- Clear the content buffer and return HTML. --->
	<cfcontent
		type="text/html"
		reset="true"
		/>

	<!---
		Even though something went wrong, provide the user
		with a fail-safe so that they can at least get to
		the new domain.
	--->
	<p>
		There was an error with the current page request.
		Please access our new site
		<a href="http://NEW_DOMAIN_HOME_PAGE">here</a>.
	</p>

</cfif>

<!--- Abort out of page. --->
<cfabort />