Need Help Making A Viable ExpandServerPath() ColdFusion UDF

<cffunction
	name="ExpandServerPath"
	access="public"
	returntype="string"
	output="false"
	hint="Expands the given path based on the callind template, not the executing script name.">

	<!--- Define arguments. --->
	<cfargument
		name="Path"
		type="string"
		required="true"
		hint="The path we are expanded."
		/>

	<!--- Define the local scope. --->
	<cfset var LOCAL = StructNew() />


	<!---
		Throw an error so that we can get the stack
		trace from the manually caught exception object.
	--->
	<cftry>
		<cfthrow
			type="ManualException"
			message="This is a planned exception."
			/>

		<!--- Catch the exception. --->
		<cfcatch>

			<!---
				Store the tag context array from the
				exception object. Since the first tag context
				item will be this template (the one containing
				the UDF), we will need to grab the second one.
			--->
			<cfset LOCAL.Context = CFCATCH.TagContext[ 2 ] />

		</cfcatch>
	</cftry>


	<!---
		Now that we have our tag context item, we can
		grab the directory of the template on which this
		method was called.
	--->
	<cfset LOCAL.Template = GetDirectoryFromPath(
		LOCAL.Context.Template
		) />


	<!--- Get the proper slash for this system. --->
	<cfset LOCAL.Slash = Right(
		LOCAL.Template,
		1
		) />


	<!---
		Clean the path that was passed into the document.
		We want to switch all slashes to be the proper slash
		for the expanded path.
	--->
	<cfset ARGUMENTS.Path = ARGUMENTS.Path.ReplaceAll(
		"[\\\/]",
		"\#LOCAL.Slash#"
		) />

	<!---
		Now that we have the proper directory, we are
		going to need to apply the standard path actions
		(such as ./ and ../). In order to do so, we are
		going to loop over the path to expand as if it
		were a list and apply each element.
	--->
	<cfloop
		index="LOCAL.PathElement"
		list="#ARGUMENTS.Path#"
		delimiters="#LOCAL.Slash#">

		<!--- Check to see the current path element type. --->
		<cfif (LOCAL.PathElement EQ ".")>

			<!---
				This is a "same directory" construct. These
				don't really need to be applied and can just
				be dropped from the path.
			--->

		<cfelseif (LOCAL.PathElement EQ "..")>

			<!---
				This is a "move up one directory" directive.
				For this, we need to remove the final slash
				and directory name from the exsisting template
				path.
			--->
			<cfset LOCAL.Template = LOCAL.Template.ReplaceFirst(
				"[^\\\/]+[\\\/]$",
				""
				) />

		<cfelse>

			<!---
				We are dealing with an actual path element. Add
				it to the existing path followed by a slash.
			--->
			<cfset LOCAL.Template = (
				LOCAL.Template &
				LOCAL.PathElement &
				LOCAL.Slash
				) />

		</cfif>

	</cfloop>


	<!---
		At this point, we have an expanded path that has a
		trailing slash. However, we only want the trailing
		slash if the path passed into this method had a
		trailing slash. Other wise, we just want to leave
		it as it came in (assuming that it was a file).
	--->
	<cfif (Right( ARGUMENTS.Path, 1 ) NEQ LOCAL.Slash)>

		<!--- Remove last slash. --->
		<cfset LOCAL.Template = LOCAL.Template.ReplaceFirst(
			"[\\\/]$",
			""
			) />

	</cfif>


	<!--- Return the expanded path. --->
	<cfreturn LOCAL.Template />
</cffunction>

#ExpandServerPath( "./data/2007_07_02.dat" )#