Performing Disaster Recovery After A ColdFusion Page Timeout Exception

<cffunction
	name="KillTime"
	access="public"
	returntype="void"
	output="false"
	hint="I kill time for the given miliseconds.">

	<!--- Define arguments. --->
	<cfargument name="MS" type="numeric" required="true" />

	<!--- Get start and end tick out values. --->
	<cfset var intStart = GetTickCount() />
	<cfset var intEnd = (intStart + ARGUMENTS.MS ) />

	<!--- Loop until this time is killed. --->
	<cfloop condition="(GetTickCount() LT intEnd)">

		<!--- Just try to kill some processing time. --->
		<cfset intStart = (intStart * Pi()) />

	</cfloop>

	<!--- Return out. --->
	<cfreturn />
</cffunction>



<!---
	Set the current time out to be 2 seconds. We are
	setting this intentionally low because we want the
	page request to timeout.
--->
<cfsetting requesttimeout="2" />

<!--- Try to kill some time. --->
<cftry>

	<!---
		Here, we are killing time - 4 seconds to be
		approximate. This will exceed the request time
		out set above (2 seconds) and will throw an error.
	--->
	<cfset KillTime( 4000 ) />


	<!---
		The KillTime() method call has timed out (just
		as we expected it to).
	--->
	<cfcatch>

		<!---
			Since we just caught an page timeout error, let's
			set a new request time out that is high enough to
			definitely let the page continue running. We HAVE
			to do this because the line of code after this
			requires too much processing time to run in the
			15-30 miliseconds that we have left to work with.
		--->
		<cfsetting requesttimeout="10" />


		<!---
			Now that we have some cushion time, let's use
			the page and fusion context objects to get the
			date/time stamp at which this page started
			processing. Then, get the number of seconds
			that that start date is smaller than the current
			date/time stamp value.
		--->
		<cfset intRunTimeInSeconds = DateDiff(
			"s",
			GetPageContext().GetFusionContext().GetStartTime(),
			Now()
			) />


		<!---
			Now that we know how long the page has been running,
			let's create a new timeout setting with that time
			plus whatever additional time we feel is necessary
			to perform our disaster recovery. In this case, we
			are going to add an additional 5 seconds. This will
			override the "Safe" CFsetting we ran above.
		--->
		<cfsetting
			requesttimeout="#(intRunTimeInSeconds + 5)#"
			/>


		<!--------------------------------------->
		<!--- Perform disaster recovery here. --->
		<!--------------------------------------->

	</cfcatch>

</cftry>


<!--- Get the new run time in seconds for the page. --->
<cfset intRunTimeInSeconds = DateDiff(
	"s",
	GetPageContext().GetFusionContext().GetStartTime(),
	Now()
	) />


<!--- Output that run time. --->
<p>
	The page has been processing for:
	#intRunTimeInSeconds# Seconds.
</p>