Calling ColdFusion Function Literals Like You Do In Javascript

// Replace a value in a text field.
strText.replace(
	new RegExp( "[0-9]", "g" ),
	function( $0 ){
		return( "blam" )
	}
	);

<!--- Store some text. --->
<cfsavecontent variable="strText">
	For a good time, give Cindy a call at
	212-555-1245. But, if you are feeling especially
	naughty, try calling Betty at 555.5534.
</cfsavecontent>


<!---
	Replace the phone number formatting using
	our passed in function.
--->
<cfset strNewText = REReplaceWithMethod(
	Text = strText.Trim(),
	RegEx = "(?:(\d{3})[ .-])?(\d{3})[ .-](\d{4})",
	Method =
		"function( $0, $1, $2, $3 ){
			if (Len( $1 )){
				return( '(##$1##) ##$2##-##$3##' );
			} else {
				return( '##$2##-##$3##' );
			}
		}"
	) />

<cffunction
	name="REReplaceWithMethod"
	access="public"
	returntype="string"
	output="false"
	hint="This takes a string, a regular expression, and a method against which each matching will be applied for the given replace.">

	<!--- Define arguments. --->
	<cfargument
		name="Text"
		type="string"
		required="true"
		hint="This is the text value we are going to manipulate."
		/>

	<cfargument
		name="RegEx"
		type="string"
		required="true"
		hint="This is our JAVA regular exiression."
		/>

	<cfargument
		name="Method"
		type="string"
		required="true"
		hint="This is our function string literal that we will we use to evaluate each match."
		/>


	<!--- Define the local scope. --->
	<cfset var LOCAL = StructNew() />

	<!---
		Create a UUID for our call back method. We are using
		UUID to help ensure that are given file name will
		not conflict with an existing file.
	--->
	<cfset LOCAL.MethodID = (
		"$" & CreateUUID().ReplaceAll( "[^\d\w]", "" )
		) />


	<!---
		Create a file path for the actual ColdFusion method.
		We are going to write this to the same directory
		this template is in.
	--->
	<cfset LOCAL.FilePath = (
		GetDirectoryFromPath( GetCurrentTemplatePath() ) &
		LOCAL.MethodID
		) />


	<!---
		Write method to disk. Since the function literal
		is passed in a string, we need to surround it with
		CFScript tags. Additionally, as the method is passed
		in without a name, we need to name it using our
		generated method ID.
	--->
	<cffile
		action="WRITE"
		file="#LOCAL.FilePath#"
		output="<cfscript>#ReplaceNoCase( ARGUMENTS.Method, 'function(', 'function #LOCAL.MethodID#(', 'ONE' )#</cfscript>"
		/>


	<!---
		Include the file. Since we are in a free-floating UDF,
		this new method is going to be stored in the current
		VARIABLES scope.
	--->
	<cfinclude template="./#LOCAL.MethodID#" />


	<!---
		Delete the file. The UDF has been loading into
		ColdFusion memory. We no longer need the file.
		THIS IS NOT EFFICIENT!
	--->
	<cffile
		action="DELETE"
		file="#LOCAL.FilePath#"
		/>


	<!---
		Get a pointer to the method. The function named with
		our given method iD has been stored in the calling
		page's VARIABLES scope.
	--->
	<cfset LOCAL.Method = VARIABLES[ LOCAL.MethodID ] />

	<!---
		Get the method parameters. We are going to be calling
		this method using CFInvoke so we need to know what the
		arguments are called. This requires the use of NAMED
		arguments.
	--->
	<cfset LOCAL.MethodParams = GetMetaData( LOCAL.Method ).Parameters />


	<!---
		Create a Java Patterns object and compile the passed
		in regular expression.
	--->
	<cfset LOCAL.Pattern = CreateObject(
		"java",
		"java.util.regex.Pattern"
		).Compile(
			ARGUMENTS.RegEx
			) />


	<!--- Get the matcher. --->
	<cfset LOCAL.Matcher = LOCAL.Pattern.Matcher(
		ARGUMENTS.Text
		) />


	<!--- Create a string buffer for results. --->
	<cfset LOCAL.Buffer = CreateObject( "java", "java.lang.StringBuffer" ).Init( "" ) />


	<!---
		Keep looping over the string finding matches for
		our regular expression.
	--->
	<cfloop condition="LOCAL.Matcher.Find()">

		<!---
			For each match, we are going to pass all the
			matching group to the passed in method. We have to
			do this using CFINvoke and CFInvokeArgument and
			therefore require named arguments.
		--->
		<cfinvoke
			method="#LOCAL.MethodID#"
			returnvariable="LOCAL.GroupResult">


			<!--- Loop over the groups that we matched. --->
			<cfloop
				index="LOCAL.GroupIndex"
				from="0"
				to="#LOCAL.Matcher.GroupCount()#">


				<!---
					Get the value of the matched group. If the
					regular expression has any optional groups,
					it is possible that some of the Group()
					calls will return a NULL value. Therefore,
					it is possible that our GroupValue variable
					will be destroyed.
				--->
				<cfset LOCAL.GroupValue = LOCAL.Matcher.Group(
					JavaCast( 'int', LOCAL.GroupIndex )
					) />

				<!---
					Check to see if we have any arguments in our
					method left to use. If the RegEx and the
					method literal are not quite aligned, we
					might have too few available arguments.
				--->
				<cfif (LOCAL.GroupIndex LT ArrayLen( LOCAL.MethodParams ))>

					<!---
						Check to see if we have a value. If we
						do not, then we are just going to send
						over the empty string. This will help to
						avoid some ColdFusion errors.
					--->
					<cfif StructKeyExists( LOCAL, "GroupValue" )>

						<!--- Send over the group argument. --->
						<cfinvokeargument
							name="#LOCAL.MethodParams[ LOCAL.GroupIndex + 1 ].Name#"
							value="#LOCAL.GroupValue#"
							/>

					<cfelse>

						<!---
							Since the group was not matched,
							send over the empty string.
						--->
						<cfinvokeargument
							name="#LOCAL.MethodParams[ LOCAL.GroupIndex + 1 ].Name#"
							value=""
							/>

					</cfif>

				</cfif>

			</cfloop>

		</cfinvoke>


		<!---
			Now that we have returned a value from the
			passed in method, we can append this replacement
			to the results buffer. We have to escape
			RegEx-type characters as they will be evaluated.
		--->
		<cfset LOCAL.Matcher.AppendReplacement(
			LOCAL.Buffer,
			LOCAL.GroupResult.ReplaceAll( "([\$\\])", "\\$1" )
			) />

	</cfloop>


	<!--- Append the remaining tail to the buffer. --->
	<cfset LOCAL.Matcher.AppendTail(
		LOCAL.Buffer
		) />


	<!---
		Return the value, converting our running results
		buffer into a string.
	--->
	<cfreturn LOCAL.Buffer.ToString() />
</cffunction>