Experiment: Modeling Complex Data Structures As Nested Query Objects In Lucee CFML 5.3.6.61

<cfscript>

	// EXPERIMENT: One of the things I love about ColdFusion is the ease with which we
	// can consume the Query object. As such, I wonder what would it look like to
	// actually model a complex data-type as a Query object, complete with NESTED QUERY
	// values. To explore, let's cast this collection of Contacts into a Query recordset.
	contactsQuery = wrapContacts([
		{
			name: "Johnny Cab",
			email: "johnny.cab@totalrecall.movie",
			isFavorite: true,
			phoneNumbers: [
				{ type: "work", number: "+1 917-555-9552" }
			],
			tags: [ "Taxi", "Cab", "Car Service", "Movie References" ],
			createdAt: createDate( 2019, 7, 13 )
		},
		{
			name: "Bella's Bakery",
			email: "baker@bellasbakery.made.up",
			phoneNumbers: [
				{ type: "work", number: "+1 212-555-0032", isPrimary: true },
				{ type: "work", number: "+1 212-555-0033" },
				{ type: "work", number: "+1 212-555-0034" }
			],
			tags: [ "Bakery", "Cookies", "Munchies" ],
			createdAt: createDate( 2014, 2, 9 )
		}
	]);

	// ------------------------------------------------------------------------------- //
	// ------------------------------------------------------------------------------- //

	// And, now that we have the Contacts modeled as a series of nested Query objects,
	// let's try to iterate over nested Query objects! Like a boss! Note that we are
	// performing CFLoop operations on the nested query objects the same way we would
	// perform them on a top-level query object.
	```
	<cfoutput>
		<cfloop query="contactsQuery">

			<h3>
				#contactsQuery.name#

				<cfif contactsQuery.isFavorite>
					( &starf; )
				</cfif>
			</h3>

			<p>
				Added #contactsQuery.createdAt.dateFormat( "mmmm d, yyyy" )#
			</p>

			<cfif contactsQuery.tags.recordCount>
				<p>
					<cfloop query="contactsQuery.tags">
						[ #contactsQuery.tags.tag# ]
					</cfloop>
				</p>
			</cfif>

			<ul>
				<cfloop query="contactsQuery.phoneNumbers">
					<li>
						#contactsQuery.phoneNumbers.number#

						<cfif contactsQuery.phoneNumbers.isPrimary>
							( &starf; )
						</cfif>
					</li>
				</cfloop>
			</ul>

			<cfif ( contactsQuery.currentRow lt contactsQuery.recordCount )>
				<hr />
			</cfif>

		</cfloop>
	</cfoutput>
	```

	// ------------------------------------------------------------------------------- //
	// ------------------------------------------------------------------------------- //

	/**
	* I cast the given contacts collection as a Query object. The "phoneNumbers" and
	* "tags" properties are composed as sub-Query objects.
	* 
	* @contacts I am the collection being cast as a Query.
	*/
	public query function wrapContacts( contacts ) {

		// NOTE: I didn't even know there was an "OTHER" type. In fact, there were also
		// "ARRAY" and "STRUCT" types in the list of supported SQL types; but, I decided
		// to stick with "OTHER" for now.
		var results = queryDefine([
			name: "varchar",
			email: "varchar",
			isFavorite: "boolean",
			phoneNumbers: "other",
			tags: "other",
			createdAt: "timestamp"
		]);

		for ( var contact in contacts ) {

			results.addRow({
				name: contact.name,
				email: contact.email,
				isFavorite: ( contact.isFavorite ?: false ),
				phoneNumbers: wrapPhoneNumbers( contact.phoneNumbers ),
				tags: wrapTags( contact.tags ),
				createdAt: contact.createdAt
			});

		}

		return( results );

	}


	/**
	* I cast the given phoneNumbers collection as a Query object.
	* 
	* @phoneNumbers I am the collection being cast as a Query.
	*/
	public query function wrapPhoneNumbers( required array phoneNumbers ) {

		var results = queryDefine([
			type: "varchar",
			number: "varchar",
			isPrimary: "boolean"
		]);

		for ( var phoneNumber in phoneNumbers ) {

			results.addRow({
				type: phoneNumber.type,
				number: phoneNumber.number,
				isPrimary: ( phoneNumber.isPrimary ?: false )
			});

		}

		return( results );

	}


	/**
	* I cast the given tags collection as a Query object.
	* 
	* @tags I am the collection being cast as a Query.
	*/
	public query function wrapTags( required array tags ) {

		var results = queryDefine([
			tag: "varchar"
		]);

		for ( var tag in tags ) {

			results.addRow({
				tag: tag
			});

		}

		return( results );

	}


	/**
	* I return a Query object with the given column definitions. I just provide a key-
	* value abstraction over the queryNew() constructor.
	* 
	* @columns I am the column types.
	*/
	public query function queryDefine( required struct columns ) {

		var names = [];
		var types = [];

		loop
			key = "local.name"
			value = "local.type"
			struct = columns
			{

			names.append( name );
			types.append( type );

		}

		return( queryNew( names, types ) );

	}
	
</cfscript>