Sending MMS (Multimedia Messaging Service) Messages With Twilio And ColdFusion

<cfscript>

	// Include the credentials for both Amazon S3 as well as Twilio.
	include "./credentials.cfm";


	// ------------------------------------------------------ //
	// ------------------------------------------------------ //


	// -- Step 1: Push Asset to Amazon S3. -- //

	// When sending MMS (Multimedia Messaging Service) messages, we
	// need to provide a URL for the multimedia asset. As such, we will
	// need to upload it to Amazon S3 first, before we can send the
	// message via Twilio.
	content = fileReadBinary( expandPath( "./monkey.jpg" ) );

	// Define the Amazon S3 resource.
	resource = "/#aws.bucket#/twilio/monkey.jpg";

	// S3 has a limited window for when a request is valid. We need
	// to tell it when this request was prepared.
	currentTime = getHttpTimeString( now() );

	// The mime-type will be stored as Meta-data on the S3 resource;
	// Amazon will also provide this as the Content-Type header when
	// serving the file.
	contentType = "image/jpeg";

	// Set up the S3 signature assets.
	// --
	// NOTE: I am setting the Amazon S3 resource as "PUBLIC-READ"; this
	// way, we do NOT have to generate a pre-signed URL for Twilio -
	// we can provide a URL directly to this resource.
	stringToSignParts = [
		"PUT",
		"",
		contentType,
		currentTime,
		"x-amz-acl:public-read",
		resource
	];

	stringToSign = arrayToList( stringToSignParts, chr( 10 ) );

	// Generate the Hmac-SHA1 of the signature.
	signature = new Crypto().hmacSha1(
		aws.secretKey,
		stringToSign,
		"base64"
	);

	// Upload the image asset to Amazon S3.
	s3Request = new Http(
		method = "put",
		url = "https://s3.amazonaws.com#resource#"
	);

	s3Request.addParam(
		type = "header",
		name = "Authorization",
		value = "AWS #aws.accessID#:#signature#"
	);

	s3Request.addParam(
		type = "header",
		name = "Content-Length",
		value = arrayLen( content )
	);

	s3Request.addParam(
		type = "header",
		name = "Content-Type",
		value = contentType
	);

	s3Request.addParam(
		type = "header",
		name = "Date",
		value = currentTime
	);

	s3Request.addParam(
		type = "header",
		name = "x-amz-acl",
		value = "public-read"
	);

	s3Request.addParam(
		type = "body",
		value = content
	);

	result = s3Request.send();


	// ------------------------------------------------------ //
	// ------------------------------------------------------ //


	// -- Step 2: Send The MMS Message. -- //

	// Now that we've uploaded the asset to Amazon S3 with *PUBLIC*
	// access, we can send the MMS message via Twilio.

	// Get the full Amazon S3 resource url.
	mediaUrl = "https://s3.amazonaws.com#resource#";

	// Send the MMS message via Twilio's REST API.
	twilioRequest = new Http(
		method = "post",
		url = "https://api.twilio.com/2010-04-01/Accounts/#twilio.accountSID#/Messages",
		username = twilio.accountSID,
		password = twilio.authToken
	);

	twilioRequest.addParam(
		type = "formfield",
		name = "From",
		value = twilio.phone
	);

	twilioRequest.addParam(
		type = "formfield",
		name = "To",
		value = "+1**********"
	);

	twilioRequest.addParam(
		type = "formfield",
		name = "MediaUrl",
		value = mediaUrl
	);

	twilioRequest.addParam(
		type = "formfield",
		name = "Body",
		value = "Check out this awesome monkey!!!"
	);

	result = twilioRequest.send();

</cfscript>