Getting GitHub's v3 API To Work With oAuth

<!--- Define the base URL of the v3 GitHub API. --->
<cfset baseAPI = "https://api.github.com/" />

<!---
	Set up empty authorization values. These are the values that
	we will have to clean up at the end - we'll be creating, using,
	and then destroying an authorization token.

	NOTE: This isn't the "right" way to do it - I simply don't have
	an architecture that can store authorization tokens.
--->
<cfset authorizationID = "" />
<cfset authorizationToken = "" />


<!---
	There's a number of parts of this workflow that could fail.
	And, depending on where it fails, we may have to clean up the
	Authorization that we have created. As such, wrap the workflow
	in a Try/Catch so we have an opportunity to clean up.
--->
<cftry>


	<!--- STEP 1: Get an authorization token. --->

	<!---
		Each token is associated with its own set of permissions.
		For this demo, all we want to do is get "gist" authorization
		(needed for Create permissions).
	--->
	<cfset postBody = {} />
	<cfset postBody[ "scopes" ] = [ "gist" ] />
	<cfset postBody[ "note" ] = "For single-use GitHub Gist creation." />

	<!---
		Get GitHub API Authorization. Note that we are using basic
		authentication to obtain the authorization token.
	--->
	<cfhttp
		result="apiRequest"
		method="post"
		url="#baseAPI#authorizations"
		username="#username#"
		password="#password#">

		<cfhttpparam
			type="body"
			value="#serializeJSON( postBody )#"
			/>

	</cfhttp>

	<!--- Check to see if the API response failed. --->
	<cfif !reFindNoCase( "2\d\d", apiRequest.statusCode )>

		<!--- Failed to create authorization - stop processing. --->
		<cfthrow type="AuthorizationFailed" />

	</cfif>

	<!--- Extract the API response payload. --->
	<cfset authorization = deserializeJSON( apiRequest.fileContent ) />

	<!--- Get the authorization data. --->
	<cfset authorizationID = authorization.id />
	<cfset authorizationToken = authorization.token />


	<!--- STEP 2: Create the Gist. --->

	<!--- Define the gist and its files. --->
	<cfset postBody = {} />
	<cfset postBody[ "description" ] = "oAuth exploration." />
	<cfset postBody[ "public" ] = true />
	<cfset postBody[ "files" ] = {} />
	<cfset postBody[ "files" ][ "file1.txt" ] = {} />
	<cfset postBody[ "files" ][ "file1.txt" ][ "content" ] = "Woot!" />
	<cfset postBody[ "files" ][ "file2.txt" ] = {} />
	<cfset postBody[ "files" ][ "file2.txt" ][ "content" ] = "Blam!" />

	<!---
		Post the Gist using the recently procured authorization
		token. Rather than using Basic Authentication (as we did
		above), we'll pass the oAuth token in the URL.
	--->
	<cfhttp
		result="apiRequest"
		method="post"
		url="#baseAPI#gists">

		<cfhttpparam
			type="url"
			name="access_token"
			value="#authorizationToken#"
			/>

		<cfhttpparam
			type="body"
			value="#serializeJSON( postBody )#"
			/>

	</cfhttp>

	<!--- Check to see if the API response failed. --->
	<cfif !reFindNoCase( "2\d\d", apiRequest.statusCode )>

		<!--- Failed to create gist - stop processing. --->
		<cfthrow type="GistFailed" />

	</cfif>


	<!--- Catch any errors. --->
	<cfcatch>
		<!---
			Nothing to do here - just need to make sure we don't
			break out of the page flow before we have a chance to
			clean up the Authorization.
		--->
	</cfcatch>


</cftry>


<!---
	Now that the primary workflow has concluded, let's check to see
	if we need to clean-up after ourselves. In this case, we only
	need to do something if the Authorization Token was created.
--->
<cfif len( authorizationID )>

	<!---
		Delete the authorization token. This, again, uses Basic
		Authentication.
	--->
	<cfhttp
		result="apiRequest"
		method="delete"
		url="#baseAPI#authorizations/#authorizationID#"
		username="#username#"
		password="#password#"
		/>

</cfif>