Selecting My SOTR Caffeinated Raffle Winner Using ColdFusion And Face.com's Facial Detection API

<!---
	Give this page some extra timeout wiggle room since we'll be
	uploading and then detail with image manipulation APIs.
--->
<cfsetting requesttimeout="#(60 * 2)#" />


<!--- Define the path to our images directory. --->
<cfset imageDirectory = expandPath( "./images/" ) />

<!---
	Define the image to upload for face-detection. These are
	the awesome ColdFusion developers who hooked me up with
	some caffeinated drinks when I was at Scotch on the Rocks.
--->
<cfset imageFiles = [
	"darren_walker.jpg",
	"gareth_sykes.jpg",
	"paul_klinkenberg.jpg",
	"tom_chiverton.jpg",
	"tyler_schofield.jpg"
	] />


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!---
	Create an array to hold detection results. Face.com can only
	accept one image at a time, so we'll have too loop over the
	photos and post each individually, storing the results in turn.
--->
<cfset results = [] />

<!---
	Post these photos to Face.com. Each photo will be analyzed
	for faces; each face will be returned as a "Tag" with
	positional information as well as confidence as to whether
	or not the face was an actual face.
--->
<cfloop
	index="imageFile"
	array="#imageFiles#">


	<!---
		Post the photo to the Face.com API.

		NOTE: By using a ".json" as the target web service file
		extension, we will be getting a JSON response.
	--->
	<cfhttp
		result="detectionRequest"
		method="post"
		url="http://api.face.com/faces/detect.json">

		<!--- Post credentials. --->
		<cfhttpparam
			type="url"
			name="api_key"
			value="#request.faceAPIKey#"
			/>

		<cfhttpparam
			type="url"
			name="api_secret"
			value="#request.faceAPISecret#"
			/>

		<!---
			Set the matching strength. We'll use Normal. An
			"Agressive" search might turn up more faces; but for
			our pursoses, that shouldn't be necessary (the photos
			are very clear).
		--->
		<cfhttpparam
			type="url"
			name="detector"
			value="Normal"
			/>

		<!--- Post the file (as "filename"). --->
		<cfhttpparam
			type="file"
			name="filename"
			file="#imageDirectory##imageFile#"
			mimetype="images/jpeg"
			/>

	</cfhttp>


	<!---
		Deserialize the facial detection response and save the
		data structure for evaluation.
	--->
	<cfset arrayAppend(
		results,
		deserializeJSON( detectionRequest.fileContent )
		) />

</cfloop>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!---
	At this point, we have passed each image to the Face.com and
	should have detection information. Now, we are going to take
	those results and see if we can highlight the faces in our
	images.
--->


<!--- Create an array to hold our ColdFusion images objects. --->
<cfset images = [] />

<!---
	Each of the tags within our images (as returned from Face.com)
	provides information about the face, gender, eye glasses, ears,
	and mouth. And each of these is given a confidence. To figure
	out the WINNER, we are going to which photo contains the face
	that Face.com gives the most confident detection.
--->
<cfset entries = queryNew(
	"url, confidence",
	"cf_sql_varchar, cf_sql_integer"
	) />


<!--- Loop over the results to help create the images. --->
<cfloop
	index="resultIndex"
	from="1"
	to="#arrayLen( results )#"
	step="1">


	<!--- Get a reference to this result. --->
	<cfset result = results[ resultIndex ].photos[ 1 ] />

	<!--- Create a ColdFusion image for this result. --->
	<cfset image = imageNew( "./images/#imageFiles[ resultIndex ]#" ) />

	<!---
		Get the image height and width (we can get this from the
		image, but since the result provides it already for their
		calculations, just grab it).
	--->
	<cfset imageWidth = result.width />
	<cfset imageHeight = result.height />

	<!---
		Now, loop over the "Tags". Each tag represents a facial
		detection within the current photo.
	--->
	<cfloop
		index="tag"
		array="#result.tags#">

		<!---
			Get the tag dimensions. While we have defined the image
			dimensions above as pixels, everything about the tags is
			expressed as percentage (to allow for arbitrary image
			scaling).
		--->
		<cfset tagWidth = (tag.width / 100 * imageWidth) />
		<cfset tagHeight = (tag.height / 100 * imageHeight) />

		<!---
			The coordinates of the tag are expressed as X/Y at the
			center of the tag.
		--->
		<cfset tagCenterX = (tag.center.x / 100 * imageWidth) />
		<cfset tagCenterY = (tag.center.y / 100 * imageHeight) />

		<!---
			Before we draw the box, let's define the line properties
			of the rectangle.
		--->
		<cfset strokeOptions = {
			width = 3,
			endcaps = "round"
			} />

		<!--- Set the line drawing properties. --->
		<cfset ImageSetDrawingStroke( image, strokeOptions ) />

		<!--- Draw the box around the current face (Tag). --->
		<cfset imageDrawRect(
			image,
			(tagCenterX - (tagWidth / 2)),
			(tagCenterY - (tagHeight / 2)),
			tagWidth,
			tagHeight
			) />


		<!--- Each tag is going to be an entry in our query. --->
		<cfset queryAddRow( entries ) />

		<!--- Set the query values. --->
		<cfset entries[ "url" ][ entries.recordCount ] = javaCast(
			"string",
			results[ resultIndex ].photos[ 1 ].url
			) />

		<cfset entries[ "confidence" ][ entries.recordCount ] = javaCast(
			"int",
			(
				tag.attributes.face.confidence +
				tag.attributes.gender.confidence +
				tag.attributes.glasses.confidence +
				tag.attributes.smiling.confidence
			)
			) />

	</cfloop>


	<!---
		Now that all of the tags have been applied to the image,
		store the upadated ColdFusion image object for later use.
	--->
	<cfset arrayAppend( images, image ) />


</cfloop>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<h1>
	Scotch On The Rocks Caffeinated Comrades
</h1>


<cfloop
	index="image"
	array="#images#">

	<p>
		<!--- Draw the image to the browser. --->
		<cfimage
			action="writeToBrowser"
			source="#image#"
			width="505"
			/>
	</p>

</cfloop>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!---
	Now that we have output all the images and facial detection
	boxes, it's time to see which face Face.com was most generally
	confident about.

	Re-order to the entries query by confidence.
--->
<cfquery name="entries" dbtype="query">
	SELECT
		*
	FROM
		entries
	ORDER BY
		confidence DESC
</cfquery>

<h2>
	And The Winner Is....
</h2>

<p>
	<!--- Output the winner. --->
	<cfimage
		action="writeToBrowser"
		source="#entries.url#"
		width="505"
		/>
</p>