Selecting The Seven Languages In Seven Weeks Winners

<!--- Set up the array of players. --->
<cfset players = [
	"Wilkins",
	"Mike",
	"Seth Stone",
	"Guganeshan.T",
	"Joshua Caito",
	"Joe Zack",
	"Andrew",
	"Rich",
	"Hidde-Jan",
	"dotnetCarpenter",
	"Adam Coffman",
	"Owen Pellegrin",
	"Ross Pfahler",
	"Marty",
	"Jared Cacurak",
	"Morten",
	"Greg Mefford",
	"Tracy Harms",
	"Eric Mitchell",
	"Jesse Riggins",
	"Danny Philayvanh",
	"Sharagoz",
	"Joel Neley",
	"Adam",
	"Nelle",
	"Matt Gutting",
	"Cade Cannon"
	] />


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!---
	Define a map function that maps one array onto another using
	the given function. When mapping, the following values will be
	handles as such:

	- Array - will be flattened and merged into the resultant array.
	- Value - will be added to the resultant array.
	- VOID - will not be added ot the resultant array.
--->
<cffunction
	name="arrayMap"
	access="public"
	returntype="array"
	output="false"
	hint="I map one array onto another array.">

	<!--- Define arguments. --->
	<cfargument
		name="originalArray"
		type="array"
		required="true"
		hint="I am the array being mapped."
		/>

	<cfargument
		name="mapper"
		type="any"
		required="true"
		hint="I am the function used to perform the mapping."
		/>

	<!--- Define the local scope. --->
	<cfset var local = {} />

	<!--- Define an array to hold the results of the mapping. --->
	<cfset local.results = [] />

	<!--- Loop over the array so we can map each value. --->
	<cfloop
		index="local.originalValue"
		array="#arguments.originalArray#">

		<!--- Hand this value off to the mapper function. --->
		<cfset local.mappedValue = arguments.mapper(
			local.originalValue
			) />

		<!---
			Check to make sure that a value exists. If it doesn't,
			it means that VOID was returned; as such, no mapped
			value will be added to the results.
		--->
		<cfif structKeyExists( local, "mappedValue" )>

			<!---
				We know we have a mapped value, so let's not figure
				out how we are merging it into the results array.
				Arrays will be flattened; single values will be
				added as such.
			--->
			<cfif isArray( local.mappedValue )>

				<!--- Add each value of the array individually. --->
				<cfloop
					index="local.mappedSubValue"
					array="#local.mappedValue#">

					<!--- Add the flattened values. --->
					<cfset arrayAppend(
						local.results,
						local.mappedSubValue
						) />

				</cfloop>

			<cfelse>

				<!--- Simply add the returned value. --->
				<cfset arrayAppend(
					local.results,
					local.mappedValue
					) />

			</cfif>

		</cfif>

	</cfloop>

	<!--- Return the resultant array. --->
	<cfreturn local.results />
</cffunction>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!---
	Now that we have our map function defined, we need to create a
	function that actually provides the mapping logic. For our
	purposes, we're going to keep mapping the players array onto a
	new array until we only have 2 people left. That means that our
	mapper function will be popping people out of the collection.
--->
<cffunction
	name="returnRandom"
	access="public"
	returntype="any"
	output="false"
	hint="I randomly return the given value or VOID.">

	<!--- Define arguments. --->
	<cfargument
		name="value"
		type="any"
		required="true"
		hint="I am the value being returned (maybe!)."
		/>

	<!---
		Randomly decide to return this value or not. If it is
		returned, it will be mapped onto the results array; if it
		is not, it will be removed.
	--->
	<cfif (rand() gt .25)>

		<!--- Return the given value. --->
		<cfreturn arguments.value />

	<cfelse>

		<!--- Return void. --->
		<cfreturn />

	</cfif>
</cffunction>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!---
	Now that we have all of our mapping functions in place, let's
	reduce our players collection down to a collection of 2. As we
	map, there is a chance that we will drop below 2. In that case,
	we'll have to just start over again.
--->
<cfoutput>


	<!---
		Keep looping until we stop. If we get a collection of 2,
		we will execute an explicit Break command.
	--->
	<cfloop condition="true">

		<!--- Copy our players array (set by VALUE). --->
		<cfset winners = players />


		<!--- Output the staring length. --->
		Starting Length: #arrayLen( winners )#<br />


		<!---
			Keep reducing the collection until it is less than
			or equal to 2 (we are hoping it is 2).
		--->
		<cfloop condition="(arrayLen( winners ) gt 2)">

			<!--- Reduce the collection randomly. --->
			<cfset winners = arrayMap(
				winners,
				returnRandom
				) />

			<!--- Output the new length. --->
			Current Length: #arrayLen( winners )#<br />

		</cfloop>


		<!--- Check to see if the collection contains 2 values. --->
		<cfif (arrayLen( winners ) eq 2)>

			<!---
				We have reduced properly. Stop the reduction loop
				as we have found our winners.
			--->
			<cfbreak />

		</cfif>

	</cfloop>


	<hr />

	<!--- Output the winners. --->
	Winner: #winners[ 1 ]#<br />
	Winner: #winners[ 2 ]#<br />

</cfoutput>