Ask Ben: Replacing A String That Is Not Inside Of Another String

<!--- Store some content to replace. --->
<cfsavecontent variable="content">

	Here is some content over here.

	<!-- And here is an HTML comment over here. -->

	And here is some more content over here.

</cfsavecontent>


<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->
<!--- ----------------------------------------------------- --->


<!---
	Set up the regular expression pattern. Notice that we
	are using both teh Verbose and Case-Insensitive flags.
--->
<cfsavecontent variable="patternText">(?xi)

	## I am going to match the comment pattern first since this
	## pattern is really our limiting factor (ie. if we match
	## this one, it negates any subsequent match within it).
	## NOTE: This is our first captured group.

	(
		[<]!--[\w\W]*?--[>]
	)

	## - OR -

	|

	## Now, we're going to match the pattern that we actually
	## want to replace out of the given string.
	## NOTE: This is our second captured group.

	(
		here
	)

</cfsavecontent>


<!--- Using our pattern text, let's compile a pattern. --->
<cfset pattern = createObject( "java", "java.util.regex.Pattern" )
	.compile( javaCast( "string", patternText ) )
	/>

<!---
	Create a matcher for our pattern as applied to our target
	text that we are wanting to alter.
--->
<cfset matcher = pattern.matcher(
	javaCast( "string", content )
	) />

<!--- Create a string buffer to hold our result. --->
<cfset result = createObject( "java", "java.lang.StringBuffer" ).init() />


<!---
	Keep looping over matches while the matcher can find more
	in the target string.
--->
<cfloop condition="matcher.find()">

	<!---
		Because we are searching for two patterns here within
		captured groups, we can check for the existence of
		captured groups to determine which pattern was matched.
	--->

	<!--- The comment was the first captured group. --->
	<cfset commentMatch = matcher.group( javaCast( "int", 1 ) ) />

	<!--- The target pattern was our second captured group. --->
	<cfset targetMatch = matcher.group( javaCast( "int", 2 ) ) />


	<!---
		Check to see which pattern exists - the group() method
		will return NULL if it did not match, which will delete
		the given ColdFusion variable.
	--->
	<cfif structKeyExists( variables, "commentMatch" )>

		<!---
			The comment was matched - simply add it to the results
			without any modification.
		--->
		<cfset matcher.appendReplacement(
			result,
			matcher.quoteReplacement( commentMatch )
			) />

	<cfelse>

		<!---
			The target pattern was what was matched in this case.
			As such, this time, we want to replace it.
		--->
		<cfset matcher.appendReplacement(
			result,
			javaCast( "string", "****" )
			) />

	</cfif>

</cfloop>

<!---
	Now that we're out of the matching, let's append whatever
	remains of the content (after the last match) to our
	results buffer.
--->
<cfset matcher.appendTail( result ) />


<!--- Output results. --->
<pre>#htmlEditFormat( result.toString() )#</pre>

**** is some content over ****.

<!-- And here is an HTML comment over here. -->

And **** is some more content over ****.