ColdFusion ArraySplice() Method As An Example Of A Dynamic Method Signature

<cffunction
	name="arraySplice"
	access="public"
	returntype="array"
	output="false"
	hint="I splice an array by deleting and / or adding new elements at the given index.">

	<!--- Define arguments. --->
	<cfargument
		name="array"
		type="array"
		required="true"
		hint="I am the array being manipulated."
		/>

	<cfargument
		name="index"
		type="numeric"
		required="true"
		hint="I am the index at which to start adding or removing elements to and from the array (respectively)."
		/>

	<cfargument
		name="howMany"
		type="numeric"
		required="true"
		hint="I am the number of elements that should be removed from the array, starting at the given index. If zero, no elements will be removed."
		/>

	<!---
		At this point, the method can take a variable number of
		subsequent arguments that would be the elements to insert
		into the array at the given index.

		<cfargument name="element1" />
		<cfargument name="element2" />
		<cfargument name="element3" />
		....
		<cfargument name="elementN" />
	--->

	<!--- Define the local scope. --->
	<cfset var local = {} />

	<!---
		The first thing we want to do is delete any elements from
		the array that we need to. Since ColdFusion doesn't have
		an inherent way to delete more than one item, we will have
		to perform this as a conditional loop.
	--->
	<cfset local.deleteCounter = arguments.howMany />

	<!---
		Keep deleting while the DeleteCounter is still non-zero
		AND while the array length is big enough to encompass the
		given index.
	--->
	<cfloop condition="(local.deleteCounter-- && (arrayLen( arguments.array ) gte arguments.index))">

		<!--- Delete the given item in the array. --->
		<cfset arrayDeleteAt(
			arguments.array,
			arguments.index
			) />

	</cfloop>

	<!---
		Now that we have delete any necessary elements from the
		array, we need to add any additional items, starting at
		the given instance.
	--->

	<!---
		Since we will need to keep updating the index of the
		insert, start a new pointer for that index.
	--->
	<cfset local.insertIndex = arguments.index />

	<!---
		Loop over the optional elements in the arguments. There
		may be ZERO or more of these elements.
	--->
	<cfloop
		index="local.elementIndex"
		from="4"
		to="#arrayLen( arguments )#"
		step="1">

		<!---
			When inserting, we need to make sure that the index
			of insertion is not beyond the bounds of the array.
			If it is, we need to do an append (or the insert
			will error).
		--->
		<cfif (local.insertIndex gt arrayLen( arguments.array ))>

			<!--- Append the new element. --->
			<cfset arrayAppend(
				arguments.array,
				arguments[ local.elementIndex ]
				) />

		<cfelse>

			<!--- Insert the new element. --->
			<cfset arrayInsertAt(
				arguments.array,
				local.insertIndex,
				arguments[ local.elementIndex ]
				) />

		</cfif>

		<!--- Increment insertion index. --->
		<cfset ++local.insertIndex />

	</cfloop>

	<!--- Return the updated array. --->
	<cfreturn arguments.array />
</cffunction>

<!--- Create an array of test values. --->
<cfset values = [ 1, 2, 3 ] />

<!--- Delete the last two values. --->
<cfset values = arraySplice( values, 2, 2 ) />
<!--- // [ 1 ]. --->

<!--- Insert two values at the end. --->
<cfset values = arraySplice( values, 2, 0, "A", "B" ) />
<!--- // [ 1, "A", "B" ]. --->

<!--- Insert two values at the beginning. --->
<cfset values = arraySplice( values, 1, 0, "Z", "Y" ) />
<!--- // [ "Z", "Y", 1, "A", "B" ]. --->

<!---
	Both delete the middle value and insert two more. Notice
	that delete and insert use the same index value.
--->
<cfset values = arraySplice( values, 3, 1, "*", "*" ) />
<!--- // [ "Z", "Y", "*", "*", "A", "B" ]. --->


<!--- Output the array (as a list). --->
<cfoutput>
	#arrayToList( values, ", " )#
</cfoutput>