Ask Ben: Extracting And Resizing A ZIP Archive Full Of Images With Coldfusion

<!--- Param the form fields. --->
<cfparam name="form.submitted" type="boolean" default="false" />
<cfparam name="form.name" type="string" default="" />
<cfparam name="form.archive" type="string" default="" />

<!--- Create an array for errors. --->
<cfset errors = [] />


<!---
	Define the path of our temp directory. This will be the
	directory into which our upload will be stored while it's
	being processed.
--->
<cfset tempDirectory = (
	getDirectoryFromPath( getCurrentTemplatePath() ) &
	"temp\"
	) />

<!---
	Define the path of our upload directory. This will be the
	directory in which we create our target directory (in which
	the images will be saved).
--->
<cfset uploadDirectory = (
	getDirectoryFromPath( getCurrentTemplatePath() ) &
	"upload\"
	) />


<!--- Check to see if the form has been submitted. --->
<cfif form.submitted>

	<!--- Validate the form data. --->

	<!--- Was name entered. --->
	<cfif !len( form.name )>

		<cfset arrayAppend(
			errors,
			"Please enter the name of your target folder."
			) />

	<cfelseif reFind( "[^\w_\-]", form.name )>

		<cfset arrayAppend(
			errors,
			"Your name contains invalid characters. Only alpha-numeric and _ and - are allowed."
			) />

	</cfif>

	<!--- Was archive selected. --->
	<cfif !len( form.archive )>

		<cfset arrayAppend(
			errors,
			"Please select an image ZIP file to upload."
			) />

	</cfif>


	<!---
		Check to see if we have any preliminary form errors at
		this point. If not, we can start to investigate deeper.
	--->
	<cfif !arrayLen( errors )>

		<!---
			If we have no errors yet, then we should try to upload
			the image ZIP file. At that point, we can perform some
			more validation of the ZIP and the contained files.
		--->

		<!--- Upload the selected archive file. --->
		<cffile
			result="upload"
			action="upload"
			filefield="archive"
			destination="#tempDirectory#"
			nameconflict="makeunique"
			/>

		<!---
			Store an easy short-hand for our uploaded zip file
			(since we are going to be referring to it a lot later
			on).
		--->
		<cfset targetZip = "#upload.serverDirectory#\#upload.serverFile#" />

		<!---
			Now that the archive was uploaded, let's search it for
			image files. Because the file interaction might throw
			an error (if it was not a zip), let's wrap in a try /
			catch block.
		--->
		<cftry>

			<!---
				Search target ZIP for images. We are going to limit
				our search to JPG images.
			--->
			<cfzip
				name="zippedImages"
				action="list"
				file="#targetZip#"
				recurse="true"
				filter="*.jpg"
				/>

			<!---
				Check to see if there were any images found. If
				there we none found, then this ZIP is invalid.
			--->
			<cfif !zippedImages.recordCount>

				<!--- Throw an error. --->
				<cfthrow
					type="NoImagesFound"
					message="There were no images found in the selected ZIP file."
					/>

			</cfif>


			<!--- Catch any errors about target images. --->
			<cfcatch type="NoImagesFound">

				<!--- Add error message. --->
				<cfset arrayAppend( errors, cfcatch.message ) />

			</cfcatch>

			<!--- Catch any file interaction errors. --->
			<cfcatch type="any">

				<!--- Add error message. --->
				<cfset arrayAppend(
					errors,
					"There was a problem reading your ZIP file. Make sure that the selected file is a valid ZIP archive."
					) />

			</cfcatch>

		</cftry>


		<!---
			Check to see if we have any errors. If we do, then
			something is wrong with the selected ZIP file and we
			don't need to have it on our server. Let's delete it.
		--->
		<cfif arrayLen( errors )>

			<!--- Delete the invalid zip file. --->
			<cffile
				action="delete"
				file="#targetZip#"
				/>

		</cfif>

	</cfif>


	<!---
		At this point, we've done all of the primary and secondary
		testing of the form data and the selected ZIP file. Let's
		check to see if we have any errors.
	--->
	<cfif !arrayLen( errors )>

		<!---
			There are no errors which means that conditions should
			be perfect for unzipping and resizing our images.
		--->

		<!---
			Create the path to our target directory (where we will
			be uploading the images).
		--->
		<cfset targetDirectory = "#uploadDirectory##form.name#\" />

		<!---
			Check to see if our target directory exists in our
			upload directory. If it does, then we need to stip out
			existing files. If it doesn't, then we need to crate
			it (and its sub-directories).
		--->
		<cfif directoryExists( targetDirectory )>

			<!---
				Since the directory exists, we are going to ASSUME
				that the sub-directory structure is already valid.
				As such, we are ONLY going to strip out existing
				files, leaving directories in place.

				NOTE: The reason we don't simply overwrite them
				later on is that there might be less images in the
				new zip than in the existing directory.
			--->

			<!---
				Query for files in the target diretory. We don't
				care about the sub-directories as these should be
				the ones we want to exist.
			--->
			<cfdirectory
				name="fileList"
				action="list"
				directory="#targetDirectory#"
				type="file"
				recurse="true"
				/>

			<!--- Loop over the existing images to delete. --->
			<cfloop query="fileList">

				<!--- Delete the existing files. --->
				<cffile
					action="delete"
					file="#fileList.directory#\#fileList.name#"
					/>

			</cfloop>

		<cfelse>

			<!---
				Since the target directory does not exist, we
				need to create it as well as the sub-directories
				for large, medium, and small images.
			--->

			<!---
				Create the taret directory (based on the user-
				entered name in the form submission).
			--->
			<cfdirectory
				action="create"
				directory="#targetDirectory#"
				/>

			<!--- Create our "large" image directory. --->
			<cfdirectory
				action="create"
				directory="#targetDirectory#large\"
				/>

			<!--- Create our "medium" image directory. --->
			<cfdirectory
				action="create"
				directory="#targetDirectory#medium\"
				/>

			<!--- Create our "small" image directory. --->
			<cfdirectory
				action="create"
				directory="#targetDirectory#small\"
				/>

		</cfif>


		<!---
			Now that we have our target directories in place,
			let's read in our zipped images and resize them.
			For this demo, I'm going to ASSUME that the uploaded
			images are the *large* versions and that for sake of
			simplicity, the sizes will be as follows:

			Large: 100% (dimensions)
			Medium: 50% (dimensions)
			Small: 25% (dimensions)
		--->

		<!---
			Because we are dealing again with file interaction
			(and file interaction that requires a specific file
			type), let's wrap this up in a try / catch block.
		--->
		<cftry>

			<!---
				Loop over the zipped images (that we gathered
				above when checking for valid images).
			--->
			<cfloop query="zippedImages">

				<!---
					Read the images in as a binary value (which
					we can use as the source in our image
					manipulation).
				--->
				<cfzip
					variable="imageData"
					action="readBinary"
					file="#targetZip#"
					entrypath="#zippedImages.name#"
					/>

				<!---
					Since we are uploading multiple images, I have
					decided to use the current record of the image
					query as the image name. This is only to
					prevent duplicates. Create a short hand for
					the file name here since we are going to be
					using it many times below.
				--->
				<cfset imageName = "#zippedImages.CurrentRow#.jpg" />


				<!---
					Write this image this raw, original image to
					our large image folder.
				--->
				<cffile
					action="write"
					file="#targetDirectory#large\#imageName#"
					output="#imageData#"
					/>

				<!---
					Resize the raw image to 50% for the medium
					image (and store it in the medium directory
					in same step).
				--->
				<cfimage
					action="resize"
					source="#imageData#"
					destination="#targetDirectory#medium\#imageName#"
					width="50%"
					height="50%"
					/>

				<!---
					Resize the raw image to 25% for the small
					image (and store it in the small directory
					in the same step).
				--->
				<cfimage
					action="resize"
					source="#imageData#"
					destination="#targetDirectory#small\#imageName#"
					width="25%"
					height="25%"
					/>

			</cfloop>


			<!--- Catch any file interaction errors. --->
			<cfcatch type="any">

				<!--- Add error message. --->
				<cfset arrayAppend(
					errors,
					"There was a problem reading / resizing one of the zipped images. Please make sure that all images are valid JPG images (NOTE: Try opening and resaving the images)."
					) />

			</cfcatch>

		</cftry>


		<!---
			At this point, we are done with all of our procesing -
			or, as much as we could. No matter how much we got
			through in this last step, let's delete the ZIP file
			as it no longer servers any purpose.
		--->
		<cffile
			action="delete"
			file="#targetZip#"
			/>

	</cfif>

</cfif>

<cfoutput>

	<!--- Reset the buffer. --->
	<cfcontent type="text/html" />

	<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
	<html>
	<head>
		<title>Extracting And Resizing A ZIP Archive Full Of Images With Coldfusion</title>
	</head>
	<body>

		<h1>
			Extracting And Resizing A ZIP Archive Full Of Images With Coldfusion
		</h1>

		<p>
			Please upload your image ZIP file and specify the
			name of the target directory into which the processed
			images will be put.
		</p>

		<!--- Check to see if there were any errors. --->
		<cfif arrayLen( errors )>

			<h2>
				Please review the following:
			</h2>

			<ul>
				<cfloop
					index="errorMessage"
					array="#errors#">

					<li>
						#errorMessage#
					</li>

				</cfloop>
			</ul>

		</cfif>

		<form
			action="#cgi.script_name#"
			method="post"
			enctype="multipart/form-data">

			<!--- Submission flag. --->
			<input type="hidden" name="submitted" value="true" />


			<p>
				<label>
					<strong>Folder Name:</strong><br />
					<input type="name" name="name" size="30" />
				</label>
			</p>

			<p>
				<label>
					<strong>Image ZIP:</strong><br />
					<input type="file" name="archive" size="50" />
				</label>
			</p>

			<p>
				<input type="submit" value="Upload Image Zip" />
			</p>

		</form>


		<!---
			Check to see if the form has been submitted and that
			we don't have any errors. If this is true, we can
			show the thumbnails of the uploaded images.
		--->
		<cfif (
			form.submitted &&
			!arrayLen( errors )
			)>

			<h2>
				Uploaded Images
			</h2>

			<ul>
				<cfloop query="zippedImages">

					<li>
						<img
							src="./upload/#form.name#/small/#zippedImages.CurrentRow#.jpg"
							alt="Small Image: 25%"
							style="border: 2px solid black ;"
							/>
					</li>

				</cfloop>
			</ul>

		</cfif>

	</body>
	</html>

</cfoutput>