Converting Numbers To A Character-Set Based Radix Using ColdFusion

<cffunction
	name="FormatBaseNData"
	access="public"
	returntype="string"
	output="false"
	hint="I take a demical value and then convert it to the number set defined by the passed in array.">

	<!--- Define arguments. --->
	<cfargument
		name="Value"
		type="numeric"
		required="true"
		hint="I am the numberic value that is being converted to a new radix."
		/>

	<cfargument
		name="CharacterSet"
		type="array"
		required="true"
		hint="I am the character set used in the conversion. Each character represents the number at it's array index."
		/>

	<!--- Define the local scope. --->
	<cfset var LOCAL = {} />

	<!--- Create the base string to be returned. --->
	<cfset LOCAL.EncodedValue = "" />

	<!---
		Get the length of our array. This will be our radix for
		the conversion. NOTE: Because ColdFusion arrays start at
		1, not zero, we will have to some manual offsetting when
		we perform the conversion.
	--->
	<cfset LOCAL.Radix = ArrayLen( ARGUMENTS.CharacterSet ) />

	<!---
		Get a local copy of our value as we will be updating it
		as we divide into it.
	--->
	<cfset LOCAL.Value = ARGUMENTS.Value />

	<!---
		When converting to a new radix, we need to keep dividing
		the value passed in until we hit zero (which will never
		have a remainder). However, because we always want to
		perform at least ONE division, we will break from within
		the loop if it hits zero rather than check for that
		loop conditional.
	--->
	<cfloop condition="true">

		<!--- Get the division result. --->
		<cfset LOCAL.Result = Fix( LOCAL.Value / LOCAL.Radix ) />

		<!--- Get the remainder of radix division. --->
		<cfset LOCAL.Remainder = (LOCAL.Value MOD LOCAL.Radix) />

		<!---
			Take the remainder and prepend the Radix-converted
			string to the encoded value. Remember, since we are
			using arrays that start at 1, we need to add one to
			this value.
		--->
		<cfset LOCAL.EncodedValue = (
			ARGUMENTS.CharacterSet[ LOCAL.Remainder + 1 ] &
			LOCAL.EncodedValue
			) />

		<!---
			Now that we have gotten the current, store the result
			value back into the value.
		--->
		<cfset LOCAL.Value = LOCAL.Result />

		<!---
			Check to see if we have any more value to divide into.
			Once we hit zero, we are out of possible remainders.
		--->
		<cfif NOT LOCAL.Value>
			<cfbreak />
		</cfif>

	</cfloop>

	<!--- Return the encoded value. --->
	<cfreturn LOCAL.EncodedValue />
</cffunction>


<cffunction
	name="InputBaseNData"
	access="public"
	returntype="string"
	output="false"
	hint="I take an encoded value and convert it back to demical based on the passed in character array.">

	<!--- Define arguments. --->
	<cfargument
		name="Value"
		type="string"
		required="true"
		hint="I am the encode value that is being converted back to a base 10 number."
		/>

	<cfargument
		name="CharacterSet"
		type="array"
		required="true"
		hint="I am the character set used in the conversion. Each character represents the number at it's array index."
		/>

	<!--- Define the local scope. --->
	<cfset var LOCAL = {} />

	<!--- Create the base number to be returned. --->
	<cfset LOCAL.DecodedValue = 0 />

	<!---
		Get the length of our array. This will be our radix for
		the conversion. NOTE: Because ColdFusion arrays start at
		1, not zero, we will have to some manual offsetting when
		we perform the conversion.
	--->
	<cfset LOCAL.Radix = ArrayLen( ARGUMENTS.CharacterSet ) />

	<!---
		Convert our character set to a list so that we can easily
		get the numeric value of our encoded digit.
	--->
	<cfset LOCAL.CharacterList = ArrayToList( ARGUMENTS.CharacterSet ) />

	<!---
		Reverse the string that was passed in. We are doing this
		because the right-most value is actually the smallest
		place and it will be easier for us to deal with in reverse.
	--->
	<cfset LOCAL.Value = Reverse( ARGUMENTS.Value ) />

	<!---
		Now, break the value up into an array so that we can more
		easily iterate over it.
	--->
	<cfset LOCAL.ValueArray = ListToArray(
		REReplace(
			LOCAL.Value,
			"(.)",
			"\1,",
			"all"
			)
		) />

	<!---
		Iterate over the array and convert each value to a power
		of our character set defined radix.
	--->
	<cfloop
		index="LOCAL.Index"
		from="1"
		to="#ArrayLen( LOCAL.ValueArray )#"
		step="1">

		<!---
			Convert the current digit and add it to the going sum
			of our conversion.
		--->
		<cfset LOCAL.DecodedValue += (
			(ListFind( LOCAL.CharacterList, LOCAL.ValueArray[ LOCAL.Index ] ) - 1) *
			(LOCAL.Radix ^ (LOCAL.Index - 1))
			) />

	</cfloop>

	<!--- Return the decoded value. --->
	<cfreturn LOCAL.DecodedValue />
</cffunction>

<!--- Get the HEX character set. --->
<cfset arrCharacters = ListToArray(
	"0 1 2 3 4 5 6 7 8 9 A B C D E F",
	" "
	) />

<!--- Test conversions. --->
255 => #FormatBaseNData( 255, arrCharacters )#<br />
FF => #InputBaseNData( "FF", arrCharacters )#<br />


<br />


<!---
	Get our collection of available characters that can be used
	when creating character-sensitive tiny URLs.
--->
<cfset arrCharacters = ListToArray(
	"a b c d e f g h i j k l m n o p q r s t u v w x y z A B C D E F G H I J K L M N O P Q R S T U V W X Y Z 0 1 2 3 4 5 6 7 8 9",
	" "
	) />

<!--- Test conversions. --->
255 => #FormatBaseNData( 255, arrCharacters )#<br />
eh => #InputBaseNData( "eh", arrCharacters )#<br />