Converting A Full CSS Selector To XPath Using ColdFusion

<cffunction
	name="CSSSelectorToXPath"
	access="public"
	returntype="string"
	output="false"
	hint="I convert a full CSS selector to XPath (ex. div.header p span).">

	<!--- Define arguments. --->
	<cfargument
		name="Selector"
		type="string"
		required="true"
		hint="I am the full CSS selector."
		/>

	<!--- Define the local scope. --->
	<cfset var LOCAL = {} />

	<!--- Remove all extra white space. --->
	<cfset LOCAL.Selector = Trim(
		REReplace(
			ARGUMENTS.Selector,
			"\s+",
			" ",
			"all"
			)
		) />

	<!---
		We are going to handle three different kinds of selection
		delimiters:

		[ ] = decendent
		[>] = child
		[,] = OR'ing two full selectors together.

		Because we have three delimiters that mean different
		things, we cannot treat this as a list. Rather, what we
		need to do is capture all elements of the selector.
	--->
	<cfset LOCAL.SelectorParts = REMatch(
		"(\s*>\s*)|(\s*,\s*)|(\s+)|([^\s,>]+)",
		ARGUMENTS.Selector
		) />


	<!--- Create an array of XPath selection parts. --->
	<cfset LOCAL.XPathParts = [] />

	<!---
		Start off by adding an "anywhere" selector to the
		XPath parts. This is because our CSS selector might
		match anywhere within the XHTML document.
	--->
	<cfset LOCAL.XPathParts[ 1 ] = "//" />


	<!---
		Now, let's loop over the parts of the CSS selector and
		convert those to their XPath equivalent.
	--->
	<cfloop
		index="LOCAL.SelectorPart"
		array="#LOCAL.SelectorParts#">

		<!--- Trim this selection part. --->
		<cfset LOCAL.SelectorPart = Trim( LOCAL.SelectorPart ) />

		<!---
			Check to see if we have a direct decendent
			delimiter. If so, we simply need to add a slash
			to the XPath parts.
		--->
		<cfif (LOCAL.SelectorPart EQ ">")>

			<!--- Add child tag XPath selector. --->
			<cfset ArrayAppend(
				LOCAL.XPathParts,
				"/"
				) />

		<cfelseif (LOCAL.SelectorPart EQ "")>

			<!--- Add decendant XPath selector. --->
			<cfset ArrayAppend(
				LOCAL.XPathParts,
				"//"
				) />

		<cfelseif (LOCAL.SelectorPart EQ ",")>

			<!---
				Add OR XPath selector. Because we are beginng a
				new selector, prepend the "anywhere" selector.
			--->
			<cfset ArrayAppend(
				LOCAL.XPathParts,
				"|//"
				) />

		<cfelse>

			<!---
				We have an actual element selector. Convert
				this to XPath syntax and add it to the XPath
				parts array.
			--->
			<cfset ArrayAppend(
				LOCAL.XPathParts,
				CSSElementSelectorToXPath( LOCAL.SelectorPart )
				) />

		</cfif>

	</cfloop>


	<!---
		Now that we have our XPath parts array, all we need to
		do is join it to form our full XPath selection query.
	--->
	<cfreturn ArrayToList( LOCAL.XPathParts, "" ) />
</cffunction>

<cfoutput>

	div<br />
	#CSSSelectorToXPath( "div" )#<br />
	<br />

	div p<br />
	#CSSSelectorToXPath( "div p" )#<br />
	<br />

	div p strong<br />
	#CSSSelectorToXPath( "div p strong" )#<br />
	<br />

	##data-form label<br />
	#CSSSelectorToXPath( "##data-form label" )#<br />
	<br />

	div > p<br />
	#CSSSelectorToXPath( "div > p" )#<br />
	<br />

	div p.stanza > strong<br />
	#CSSSelectorToXPath( "div p.stanza > strong" )#<br />

</cfoutput>