Winners Of My 1,000th ColdFusion Post

<cffunction
	name="GoogleRandRange"
	access="public"
	returntype="numeric"
	output="false"
	hint="I use Google's Im Feeling Lucky functionality to help pick out a random number.">

	<!--- Define arguments. --->
	<cfargument
		name="MinValue"
		type="numeric"
		required="true"
		hint="I am the lower-bound inclusive value."
		/>

	<cfargument
		name="MaxValue"
		type="numeric"
		required="true"
		hint="I am the upper-bound inclusive value."
		/>

	<!--- Define the local scope. --->
	<cfset var LOCAL = {} />

	<!--- Create a random set of keywords. --->
	<cfset LOCAL.Keywords = [
		"sexy", "muscle", "voluptuous", "saucy", "naughty",
		"protein", "hairy", "sweet", "squating", "kinky",
		"amazon", "fetish", "plump", "smooth", "fitness",
		"smile", "fresh", "pumped", "delicious", "happy"
		] />

	<!---
		Shuffle keyword array to get a new, random result from
		Google's I'm Feelin Lucky search results.
	--->
	<cfset CreateObject( "java", "java.util.Collections" ).Shuffle(
		LOCAL.Keywords
		) />

	<!--- Build the search query with the first 3 keywords. --->
	<cfset LOCAL.Criteria = (
		LOCAL.Keywords[ 1 ] & " " &
		LOCAL.Keywords[ 2 ] & " " &
		LOCAL.Keywords[ 3 ]
		) />


	<!---
		Get the first result from Google search. Wrap this in a
		Try/Catch incase it timesout and throws an error.
	--->
	<cftry>

		<!--- Grab random result. --->
		<cfhttp
			method="get"
			url="http://www.google.com/search"
			useragent="RandomizerBot"
			timeout="5"
			result="LOCAL.HttpGet">

			<!--- Referer from google. --->
			<cfhttpparam
				type="header"
				name="referer"
				value="http://www.google.com"
				/>

			<!--- The search query. --->
			<cfhttpparam
				type="formfield"
				name="q"
				value="#LOCAL.Criteria#"
				/>

			<!--- Im Feeling Lucky submit button. --->
			<cfhttpparam
				type="formfield"
				name="btnI"
				value="I'm Feeling Lucky"
				/>

		</cfhttp>

		<!--- Catch http connection errors. --->
		<cfcatch>

			<!---
				There was an error connecting to this site.
				Try another attempt.
			--->
			<cfreturn GoogleRandRange(
				ARGUMENTS.MinValue,
				ARGUMENTS.MaxValue
				) />

		</cfcatch>
	</cftry>


	<!--- Check to see if we connected. --->
	<cfif NOT FindNoCase( "200", LOCAL.HttpGet.StatusCode )>

		<!---
			The random result may have failed. Return a
			new random result.
		--->
		<cfreturn GoogleRandRange(
			ARGUMENTS.MinValue,
			ARGUMENTS.MaxValue
			) />

	</cfif>


	<!---
		ASSERT: At this point, we know that the CFHTTP get
		was successfull.
	--->


	<!--- Remove any non-word characters. --->
	<cfset LOCAL.Content = REReplace(
		LOCAL.HttpGet.FileContent,
		"[^\w]+",
		"",
		"all"
		) />

	<!--- Grab a random character in the content. --->
	<cfset LOCAL.Char = Mid(
		LOCAL.Content,
		RandRange( 1, Len( LOCAL.Content ) ),
		1
		) />


	<!--- Get the difference betweent he min and max value --->
	<cfset LOCAL.Range = (ARGUMENTS.MaxValue - ARGUMENTS.MinValue) />

	<!---
		To make sure we get a sufficiently large value from
		which to pick (increasing the randomness), let's multiple
		the selected ASCII value by the length of the content.
	--->
	<cfset LOCAL.HighAscii = (Asc( LOCAL.Char ) * Len( LOCAL.Content )) />

	<!---
		Return the lower bound value plus the MOD of the high
		ascii to the range.
	--->
	<cfreturn (
		ARGUMENTS.MinValue +
		(LOCAL.HighAscii MOD LOCAL.Range)
		) />
</cffunction>