Ask Ben: Extracting Data With Regular Expressions vs. ColdFusion List Functions

<!--- Create our test string. --->
<cfset strData = "XXXX ##YYYY **ZZZZZZZZZZ** 11111-0000" />

<!---
	Break the list up into an array. When we view this list,
	we are going to be using multiple delimiters. Since we
	don't want to gather any spaces, hashes, or stars, we can
	use all those as delimiters which will break out string
	up exactly how we want.
--->
<cfset arrData = ListToArray(
	strData,
	" ##*"
	) />

<!---
	Dump out the array of data. You will see that each part
	of the data is isolated to its own index of the newly
	formed data array.
--->
<cfdump
	var="#arrData#"
	label="Multi-Delimiter ListToArray()"
	/>

<!--- Create our test string. --->
<cfset strData = "XXXX ##YYYY **ZZZZZZZZZZ** 11111-0000" />

<!---
	Get all strings that do not include our "list" delimiters.
	Like the ListToArray() method, this will break our string
	up into the appropriate parts.
--->
<cfset arrData = REMatch(
	"[^ ##*]+",
	strData
	) />

<!---
	Dump out the array of pattern matches. You will see that
	each part of the data is isolated to its own index of the
	newly formed data array.
--->
<cfdump
	var="#arrData#"
	label="REMatch() Data"
	/>

<!--- Create our test string. --->
<cfset strData = "XXXX ##YYYY **ZZZZZZZZZZ** 11111-0000" />

<!---
	Create our pattern for matching this string. We are
	going to create a pattern that will match the ENTIRE
	test string; then, we are going to CAPTURE each target
	substring into it's own group which can be retrieved via
	the pattern matcher.

	To help explain this, I am going to build the regular
	expression in a string buffer and use the VERBOSE flag
	so that we can break it up for readability.
--->
<cfsavecontent variable="strRegEx">

	<!--- The VERBOSE flag. --->
	(?x)

	<!--- Match the start of the string. --->
	^

	<!---
		The first group is all the characters that do NOT
		include the first white space character.
	--->
	([^\s]+)

	<!---
		Our first "delimiter is the space and the hash
		(escaped for ColdFusion CFOutput - not shown).
		Because we are using VERBOSE regex, we need to
		escape the hash sign (normally we wouldn't have to
		do this).
	--->
	\s\##

	<!---
		Our next group is everthing until the next white
		space character.
	--->
	([^\s]+)

	<!---
		Our second delimiter is space and two stars. Since
		stars are special characters, we have to escape them.
	--->
	\s\*\*

	<!---
		Our next group is anything until the next star. Since
		this is in a character group, we don't have to escape it.
	--->
	([^*]+)

	<!--- Our third delimiters is two stars and a space. --->
	\*\*\s

	<!---
		Our final value (group 4) is anything until the end
		of the string.
	--->
	(.+)

	<!--- Match the end of the string. --->
	$

</cfsavecontent>

<!--- Compile our pattern. --->
<cfset objPattern = CreateObject(
	"java",
	"java.util.regex.Pattern"
	).Compile(
		JavaCast( "string", Trim( strRegEx ) )
		)
	/>

<!---
	Get a pattern matcher that will scan our target string
	for the given match and make the captured groups accessible
	by group index.
--->
<cfset objMatcher = objPattern.Matcher(
	JavaCast( "string", strData )
	) />

<!--- Check to see if we found a match. --->
<cfif objMatcher.Find()>

	<!--- We found a match, output the groups. --->
	Group 1: #objMatcher.Group( JavaCast( "int", 1 ) )#<br />
	Group 2: #objMatcher.Group( JavaCast( "int", 2 ) )#<br />
	Group 3: #objMatcher.Group( JavaCast( "int", 3 ) )#<br />
	Group 4: #objMatcher.Group( JavaCast( "int", 4 ) )#<br />

</cfif>