Ask Ben: Iterating Over An Unknown Number Of Nested Lists

<!--- Import our loop library. --->
<cfimport
	taglib="./"
	prefix="nlist"
	/>


<!--- Build our array of lists. --->
<cfset arrLists = [
	"Blue,Black",
	"Small,Medium,Large",
	"Mens,Womens",
	"Full Sleeve,Short Sleeve"
	] />


<!---
	Let's loop over our array of lists and find the
	combination for each iteration. The arrLists variable
	is our ARRAY of lists and the arrCombo is an array of
	the current values from each list iteration.
--->
<nlist:loop
	index="arrCombo"
	lists="#arrLists#"
	delimiters=",">

	<!---
		Loop over our combination to output the current
		values from each list.
	--->
	<cfloop
		index="intIndex"
		from="1"
		to="#ArrayLen( arrCombo )#"
		step="1">

		<!--- Check for formatting needs. --->
		<cfif (intIndex GT 1)>
			-
		</cfif>

		#arrCombo[ intIndex ]#

	</cfloop>

	<br />

</nlist:loop>

<!---
	This method will be used in both the start and end modes
	of this tag. It takes the current list set up and builds
	the index combo.
--->
<cffunction
	name="BuildCombo"
	access="public"
	returntype="array"
	output="false"
	hint="I build the Combo array based on the current list indexes.">

	<!--- Define the local scope. --->
	<cfset var LOCAL = {} />

	<!--- Build the current combination. --->
	<cfset LOCAL.Combo = [] />

	<!--- Loop over list to get start values. --->
	<cfloop
		index="LOCAL.ThisList"
		array="#VARIABLES.Lists#">

		<cfset ArrayAppend(
			LOCAL.Combo,
			LOCAL.ThisList.List[ LOCAL.ThisList.Index ]
			) />

	</cfloop>

	<!--- Return combo. --->
	<cfreturn LOCAL.Combo />
</cffunction>



<!--- Check to see which mode the tag is executing. --->
<cfif (THISTAG.ExecutionMode EQ "Start")>

	<!---
		We only care about the tag attributes the first time
		around - in the Start mode.
	--->

	<!---
		This is the name of the value that will be contain
		the current list values in the CALLER scope.
	--->
	<cfparam
		name="ATTRIBUTES.Index"
		type="variablename"
		/>

	<!---
		This is the array of lists over which we are going
		to iterate (loop).
	--->
	<cfparam
		name="ATTRIBUTES.Lists"
		type="array"
		/>

	<!---
		These are the delimiters that will be use for the
		individual list iterations.
	--->
	<cfparam
		name="ATTRIBUTES.Delimiters"
		type="string"
		default=","
		/>


	<!---
		First, we want to break our lists up into arrays for
		faster looping. And, since this will be very index-
		intensive alogrithm, it will help to have a data
		structure that we can quickly access by index.
	--->
	<cfset VARIABLES.Lists = [] />

	<!--- Loop over lists to move to new data struct. --->
	<cfloop
		index="VARIABLES.List"
		array="#ATTRIBUTES.Lists#">

		<!---
			When we break the lists up, we also want to store
			some other convenience values such as the current
			index of that loop and the length.
		--->
		<cfset VARIABLES.ThisList = {
			List = ListToArray(
				VARIABLES.List,
				ATTRIBUTES.Delimiters
				),
			Index = 1,
			Length = 0
			} />

		<!--- Update the lenth property. --->
		<cfset VARIABLES.ThisList.Length = ArrayLen(
			VARIABLES.ThisList.List
			) />

		<!---
			Before we add to the list, let's just double check
			to make sure that we have a length for this item.
			If the list has no lenth, it cannot be output.
		--->
		<cfif VARIABLES.ThisList.Length>

			<cfset ArrayAppend(
				VARIABLES.Lists,
				VARIABLES.ThisList
				) />

		</cfif>

	</cfloop>


	<!--- Check to see if we have any lists to work with. --->
	<cfif NOT ArrayLen( VARIABLES.Lists )>

		<!---
			The passed-in lists did not result in any usable
			combinations. Break out of tag.
		--->
		<cfexit method="exittag" />

	</cfif>


	<!---
		ASSERT: At this point, we know that we have enough data
		in our lists to perform at least one loop iteration.
		The variable VARIABLES.Lists holds the lists over which
		we need to iterate.
	--->


	<!---
		Store the index of the list over which we are currently
		iterating. To start off, this will be the last list.
	--->
	<cfset VARIABLES.CurrentList = ArrayLen( VARIABLES.Lists ) />

	<!--- Build the current combination and store in CALLER. --->
	<cfset CALLER[ ATTRIBUTES.Index ] = VARIABLES.BuildCombo() />

<cfelse>

	<!--- The END mode of the tag. --->

	<!---
		Keep trying to increment the "current" list value until
		we break out of the loop. We are doing this because we
		might have to move over more than one place (list)
		depending on the list lengths.
	--->
	<cfloop condition="true">

		<!--- Increment the index of the current list. --->
		<cfset VARIABLES.Lists[ VARIABLES.CurrentList ].Index++ />

		<!---
			Check to see if we have gone too high with the
			current list index. If the index extends past the
			length of the list, we have fully iterated over
			the current list.
		--->
		<cfif (VARIABLES.Lists[ VARIABLES.CurrentList ].Index GT VARIABLES.Lists[ VARIABLES.CurrentList ].Length)>

			<!---
				Since we are out of bounds on the current list,
				we want to set the current list index back to 1
				(reset the iteration) and then move to next list
				to continue iteration.
			--->
			<cfset VARIABLES.Lists[ VARIABLES.CurrentList ].Index = 1 />

			<!--- Move the current list over one. --->
			<cfset VARIABLES.CurrentList-- />

			<!---
				Check to see if we have a current list. If we do
				not, then we moved out of bounds and we are done
				with the iteration.
			--->
			<cfif NOT VARIABLES.CurrentList>

				<!---
					We have fully iterated over every possible
					combination of the list. Break out of the
					current tag.
				--->
				<cfexit method="exittag" />

			</cfif>

		<cfelse>

			<!---
				We have increment the current list successfully.
				Now, we want to go all the way back to the
				beginning again.
			--->
			<cfset VARIABLES.CurrentList = ArrayLen(
				VARIABLES.Lists
				) />

			<!--- Break out of this loop. --->
			<cfbreak />

		</cfif>

	</cfloop>


	<!---
		ASSERT: If we have made it this far, then we have another
		iteration to perform.
	--->


	<!--- Build the current combination and store in CALLER. --->
	<cfset CALLER[ ATTRIBUTES.Index ] = VARIABLES.BuildCombo() />

	<!--- Loop. --->
	<cfexit method="loop" />

</cfif>