Graceful ColdFusion Timeout Disaster Recovery (Thanks Barney Boisvert)

<cffunction
	name="GetRequestTimeout"
	access="public"
	returntype="numeric"
	output="false"
	hint="Returns the current request timeout for the current page page request.">

	<!--- Define the local scope. --->
	<cfset var LOCAL = StructNew() />

	<!--- Get the request monitor. --->
	<cfset LOCAL.RequestMonitor = CreateObject(
		"java",
		"coldfusion.runtime.RequestMonitor"
		) />

	<!--- Return the current request timeout. --->
	<cfreturn LOCAL.RequestMonitor.GetRequestTimeout() />
</cffunction>

<cffunction
	name="KillTime"
	access="public"
	returntype="void"
	output="false"
	hint="I kill time for the given miliseconds.">

	<!--- Define arguments. --->
	<cfargument
		name="MS"
		type="numeric"
		required="true"
		/>

	<!--- Get start and end tick out values. --->
	<cfset var intStart = GetTickCount() />
	<cfset var intEnd = (intStart + ARGUMENTS.MS ) />

	<!--- Loop until this time is killed. --->
	<cfloop condition="(GetTickCount() LT intEnd)">

		<!--- Just try to kill some processing time. --->
		<cfset intStart = Sqr(
			intStart * Pi() * GetTickCount()
			) />

	</cfloop>

	<!--- Return out. --->
	<cfreturn />
</cffunction>


<!--- ::: DEMO CODE ::: --->


<!--- Set the current time out to be 2 seconds. --->
<cfsetting requesttimeout="2" />

<!---
	Get the millisecond start time for page processing
	(so that later on, we can check to see how long
	the page ran overall).
--->
<cfset intStart = GetTickCount() />


<!--- Try to kill some time. --->
<cftry>

	<!---
		Here, we are killing time - 4 seconds to be
		approximate. This will exceed the request time
		out set above (2 seconds) and will throw an error.
	--->
	<cfset KillTime( 4000 ) />


	<!--- The KillTime() method call has timed out. --->
	<cfcatch>

		<p>
			First Timeout!
		</p>

		<!---
			Now that our page has timed out, we need to
			add more time to the request in order to recover
			gracefully. Add a few seconds onto the request
			timeout that caused this exception.
		--->
		<cfsetting
			requesttimeout="#(GetRequestTimeout() + 3)#"
			/>


		<!---
			Now that we have a little more wiggle room,
			let's email ourselves the caught exception.
		--->
		<cfmail
			to="ben@xxxxxxxx.com"
			from="no-reply@xxxxxxxx.com"
			subject="Kinky Solutions Timeout Error"
			type="html">

			<p>
				The following error was thrown on
				#DateFormat( Now(), "mmm d, yyyy" )# at
				#TimeFormat( Now(), "hh:mm TT" )#
			</p>

			<!--- Dump out error. --->
			<cfdump
				var="#CFCATCH#"
				label="Kinky Solutions Exception"
				/>

			<!--- Dump out CGI object. --->
			<cfdump
				var="#CGI#"
				label="CGI Struct"
				/>
		</cfmail>

	</cfcatch>

</cftry>


<cfoutput>
	<p>
		Total Time: #(GetTickCount() - intStart)#
	</p>
</cfoutput>