ColdFusion 10 - Creating A Simple Expression Evaluator

Yesterday, I was looking at ColdFusion 10's native WebSocket filtering functionality. It uses the special data key, "selector," as a way to define message filtering criteria. Last night, I started to think about how I could replicate this behavior in my WSApplication.cfc WebSocket proxy when it occurred to me that I needed a way to evaluate an expression in the context of a given object. Now that the function local scope is available as a named scope (as of ColdFusion 9), we can create a very simple expression evaluator with a little bit of scope concatenation.

NOTE: At the time of this writing, ColdFusion 10 was in public beta.

To quickly recap, ColdFusion 10's native WebSocket filtering works using the delayed evaluation of a selector expression:

selector: "userID eq 5"

This expression, "userID eq 5", is evaluated in the context of each subscriber when a message is being sent out. This means that the "userID" variable within the expression is meant to be found within the Subscriber object. I believe that ColdFusion 10 is using an advanced expression evaluation library under the hood (maybe Java's Unified Expression Language); but, for simple expressions, we can leverage the function Local scope to the same effect:

<cfscript>


	// I evaluate the given expression in the context of the given
	// context object (for variable look-up).
	evaluateExpression = function( context, expression ){

		// Copy the context object to the look-up.
		structAppend( local, context );

		// Evaluate the expression in the context of the current
		// local scope, which has been augmented with the contents
		// of the context object.
		return( evaluate( expression ) );

	};


	// ------------------------------------------------------ //
	// ------------------------------------------------------ //


	// Create a context object.
	friend = {
		name: "Tricia",
		age: 35
	};


	// Evaluate the expression in the given context.
	condition = evaluateExpression(
		friend,
		"(name eq 'Tricia') && (age gt 30)"
	);

	// Output the evaluated result.
	writeOutput( "Result: " & condition & "<br />" );


	// Evaluate the expression in the given context.
	condition = evaluateExpression(
		friend,
		"len( name ) eq 3"
	);

	// Output the evaluated result.
	writeOutput( "Result: " & condition & "<br />" );


</cfscript>

In this demo, we're leveraging the fact that the function local scope is one of the implicit scopes searched for unscoped variable reference resolution. By appending the context object to the local scope, it allows the expression to access context-scoped values without a scope. And, in fact, when we run the above code, we get the following output:

Result: YES
Result: NO

Clearly, this won't work for all types of contexts (ex. ColdFusion components). But, for simple Scopes, this seems to be the low-hanging-fruit solution.

Want to use code from this post? Check out the license.

Short link: https://bennadel.com/2353