Deleting ColdFusion Scheduled Tasks With CFThread And CFSchedule
Posted December 29, 2008 at 12:09 PM
If you can remember this far back, a little over two years ago I stumbled upon the odd fact that in ColdFusion a scheduled task cannot delete itself. As a very hacky work around to this, I came up with a way to use ColdFusion's CFHTTP tag to have the scheduled task launch an asynchronous request that was able to delete the original scheduled task. This worked, but is clearly not ideal. Now, with ColdFusion 8's CFThread tag, we have a much cleaner way to launch asynchronous tasks. As such, I figured I would take a few minutes to see if it could be used to delete scheduled tasks.
I created a scheduled task named, "CFThreadDelete," that calls this template ever 61 seconds (ColdFusion scheduled tasks cannot fire more often than 61 seconds):
Launch code in new window » Download code as text file »
- <!--- Get the file path of our log file. --->
- <cfset strLogFile = ExpandPath( "./log.txt" ) />
-
- <!---
- Log task output. We are doing this so we can see when the
- task fires and whether or not the CFSchedule tag successfully
- deleted the task.
- --->
- <cffile
- action="append"
- file="#strLogFile#"
- output="Triggered: #DateFormat( Now(), 'HH:mm:ss' )#"
- addnewline="true"
- />
-
-
- <!--- Check to see if we should delete this task. --->
- <cfif (RandRange( 1, 3 ) EQ 2)>
-
- <!---
- Delete the scheduled task. Since a task cannot delete
- itself from the same thread, we need to launch a seprate
- thread to actually execute the CFSchedule tag.
- --->
- <cfthread
- action="run"
- name="DeleteTask"
- logfile="#strLogFile#">
-
- <!--- Log the deletion attempt. --->
- <cffile
- action="append"
- file="#ATTRIBUTES.LogFile#"
- output="Deleted: #DateFormat( Now(), 'HH:mm:ss' )#"
- addnewline="true"
- />
-
- <!--- Delete the task. --->
- <cfschedule
- action="delete"
- task="CFThreadDelete"
- />
-
- </cfthread>
-
- </cfif>
-
-
- <p>
- Task Done Executing
- </p>
As you can see, each time the template runs, I am logging the request to a text file. Then, I randomly generate a number to see if we should delete the current task. If, by chance, we need to delete the task, I am launching a parallel thread using ColdFusion 8's CFThread tag. This asynchronous process then logs the delete request and uses CFSchedule to delete the named task.
After letting this run for about 10 minutes, I checked the log file:
Triggered: 11:12:48
Deleted: 11:12:49
Looks like the task ran once and, by chance, deleted itself on the first run. Now, since I left it to run for 10 minutes, I am quite confident that the task is not still running. The ColdFusion Administrator also reports the task as no longer existing.
Looks like ColdFusion 8's CFThread tag can be used to quite elegantly delete scheduled tasks that want to auto-distruct.
Download Code Snippet ZIP File
Post Comment | Ask Ben | Other Searches | Print Page
Newer Post
Project HUGE: Active Release Technique (ART) With Dr. Christopher Anselmi In NYC
Older Post
Ask Ben: Handling Optional XML Nodes In WhitePages.com API Response
Reader Comments
I got intrigued by this post, as it struck me a little too complex for something that should be fairly simple.
I have never had any issues just inserting the code to delete the scheduled task inside the actual task, so it deletes itself when it is done.
Here's some older info I reposted from my notes. http://blog.shortfusion.com/index.cfm/2008/12/29/Dynamic-Scheduled-Tasks-With-ColdFusion#more
Hi Ben,
I always like seeing new ways of using cfthread, but I have to second Alex on this. This may be new to CF8, but I've also managed to have a scheduled task delete itself (it's actually the first thing I do in the task).
@Alex,
Interesting post. The way you have it set up, it doesn't matter. Without a parallel thread, when you scheduled task deletes itself, it does successfully remove itself form the ColdFusion Admin; however, the task will continue to execute on its existing scheduled basis until the ColdFusion service is restarted.
However, since your task interval was "ONCE", even if the scheduled task hangs out in memory (as it should with the "bug"), it will never fire again. If you changed your task to something reoccurring, you would probably experience some issues.
@Francois,
See my previous comment. I wonder what repeating occurrence your tasks have.
@Ben,
Ah, there you go. I imagine the little detail about the interval "bug" was in your previous post. My bad ;).
@Francois,
No worries my man. And to be honest, I have only ever dealt with tasks that happen on a regular basis. It's certainly possible that there is no bug for one-off tasks. Perhaps the mechanism for how the task interval is defined is where the bug is.
Hi Ben,
I'm wondering if you have had any experience using alternative scheduling software?
I recently took a look at Quartz (http://www.opensymphony.com/quartz/), and I may end up using in one of projects. I really like the fact that it solves all the inherent weakness of scheduled tasks, e.g. proper queuing, flexible start times (no 61 second wait).
Integration may be a bit of a challenge, so I'm wondering if you have any different recommendations?
Thanks,
Jim
@Jim,
I have not tried anything else.
I am having an issue now that even if I delete a scheduled task in the admin. It keeps firing off and the old scheduled interval. Even restarting CF doesn't help. As a temporary measue I have just deleted the template it is trying to run but every two minutes I get an entry in application log that it cannot find the file.
@Don,
Sounds like the config file that stores the scheduled tasks is corrupted or something?? Very strange. If restarted the ColdFusion service doesn't get rid of it AND it's no longer in the ColdFusion admin, then something very odd is going on.
